in reply to Failed array attemp

imho, the ternary (?:) operator isn't really meant to perform side effects. It was designed to select from two separate values:

$x = (1 == 1)
  ? 'true'
  : 'false'

[download]

'true' is put into $x if 1==1, and 'false' otherwise. Here's a way that does what you need, still using the ternary operator:

#!/usr/bin/perl

use warnings;
use strict;

use List::Util qw (first);

my @a = qw( 1 2 3 4 5 );
my @b = qw( 9 8 2 1 5 );

my @z;

for my $elem ( @a ){
    my $result = ( first { $elem == $_ } @b )
        ? '+'
        : '-';

    push @z, $result;
}

print @z;

[download]

Output:

++--+

Edit: Changed from using alpha to using numeric as to not confuse the OP with 'eq'.

Update: Please see this post by Anomalous Monk as to why my choice of using first() from List::Util should be replaced with any() from List::MoreUtils. It's a drop-in replacement in fact.

Replies are listed 'Best First'.
Re^2: Failed array attemp
by Anonymous Monk on May 13, 2012 at 21:31 UTC
    Thanks for that.If I should not really do it this way what would be a best and shortest method?
[reply]
      for my $elem ( @a ){
    push @z, $_ = ( first { $elem eq $_ } @b ) ? '+' : '-';
}

      [download]
[reply]
[d/l]
        for my $elem ( @a ){
    push @z, $_ = ( first { $elem eq $_ } @b ) ? '+' : '-';
}

        [download]

        One problem with this code is that  first returns the first element from  @a that is also present in  @b. If there is a 0 in both  @a and  @b a 0 will be returned. Numeric 0 is false, which will cause the ternary to select the '-' character representing element not present.

        In addition, the code needlessly assigns to the  $_ scalar. In the example below, comment out the  local $_; statement and see what happens to the  $_ scalar.

        IMHO, using  any (as in the OPed code) is far better. The job can also be done with the  map built-in rather than a  for loop. 

        >perl -wMstrict -MData::Dump -le
"use List::Util      qw(first);
 use List::MoreUtils qw(any);
 ;;
 my @a = (1, 2, 3, 4, 5);
 my @b = (9, 8, 2, 1, 5);
 my @z;
 ;;
 $_ = 'foo';
 { local $_;
   for my $elem ( @a ){
     push @z, $_ = ( first { $elem eq $_ } @b ) ? '+' : '-';
     }
   }
 print @z;
 print qq{\$_ == '$_'};
 ;;;;
 @z = ();
 for my $elem (@a) {
   push @z, (any { $_ == $elem } @b) ? '+' : '-';
   }
 print @z;
 ;;;;
 @z = map { my $ae = $_;  (any { $ae == $_ } @b) ? '+' : '-' } @a;
 print @z;
"
++--+
$_ == 'foo'
++--+
++--+

        [download]

        Update: Another oops. In the first for-loop example above, the statement
            push @z,  ( first { $elem eq $_ } @b ) ? '+' : '-';
        was intended to exactly duplicate the corresponding statement in the post to which I was responding. I took out the  $_ = assignment to test something, then forgot to put it back. I have now put the assignment back; the output is the same, and removing the  local $_; statement now will really change the output.

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom