There are two main ways to do it:

1. Use some sort of HTML or DOM parsing module, have it pick out the element of the page containing your date, and then go up the chain of parents until you get something that contains all the info you want. Looking at the page in your link, the date would be in a <span> tag, which is inside a <p>, which is inside a <td>, which is inside a <tr>, which appears to contain the info you want. So you'd have to point to the correct span and then get its parent's parent's parent, and either parse the text out of that or plug that <tr> into a <table> of your own. Exactly how to do that process will depend on what module you use. With something like Mojo::DOM, it could look something like this ('ve barely used it, but it looks a lot like jQuery which I'm familiar with, so I think this is close):

for my $e ($dom->find('span')->each) {
  if($e->text =~ /$mydate/ ){
    my $myhtml = $e->parent->parent->parent->text;
    # do stuff with $myhtml
  }
}
[download]

2. Parse the data from the raw HTML with your own regular expressions. See example below. Regexes like this tend to be tricky to create and brittle, because they're liable to break as soon as the page design changes at all. (So will a DOM/parser method if the nesting of the elements changes, but a regex may break just because they start capitalizing a tag.) But for a quick-and-dirty hack that you're using for your own use, it gets the job done.

#!/usr/bin/env perl
use Modern::Perl;
use LWP::Simple;

my $date = $ARGV[0] || '4/23/012';
my $page =
get('http://staweb.sta.cathedral.org/departments/math/mhansen/public_h
+tml/1112hcal/1112hcal.htm');
die "Couldn't get page" unless $page;
my( $assignment ) = $page =~ m{ $date .+? <span .+?>(.+?)</span>\s*</p
+> }sx;
say $assignment;
[download]

#!/usr/bin/perl
# find calc homework

use strict;
use warnings;


use HTML::TreeBuilder;

my $date='4/27/012';        #set the date, you can do this dynamically

my $url= 'http://staweb.sta.cathedral.org/departments/math/mhansen/pub
+lic_html/1112hcal/1112hcal.htm';

# get the page and make a tree structure out of it
my $tree= HTML::TreeBuilder->new_from_url($url);    

#break the table into rows
my @elements = $tree->find_by_tag_name('tr');         

#loop through the rows looking for the date
#and use the as_trimmed_text to get rid of all the extra htmlness
foreach (@elements){                        
    if((my $hw=$_->as_trimmed_text())=~m%$date%){    
        print $hw."\n";
    }

}
[download]

It takes approach 1 that aaron_baugher describes, but mostly ignores the details of the page structure. We know it's a table and we want the rows. Knowing that the first column is just the day and date, I'm going to assume we want to keep them anyway. The find_by_tag_name just gets all the rows and all the stuff inside them. There's a bunch of <p> and <span> tags that really aren't interesting, so I take the lazy approach and use as_trimmed_text to throw those away and just keep the contents of the two cells all together. It's also useful to know that HTML::TreeBuilder gets a bunch of methods from HTML::Element.

Update: tweaked the code formatting to keep the comments from wrapping

...And to note that some of your assignments have links in them-- you can use HTML::Element to dig those out before you apply as_trimmed_text, or dig them out an of other various possible ways.