Always use strict; use warnings; it would tell you what's wrong.

There are two problems with your code. The first is that compare strings with ==, even though that operator does numeric comparison. And the second is that if there are only two chunks in the original string, $split_data[2] will not be the empty string, but undef.

So your test should look more like

if (!defined($split_data[2]) || $split_data[2] eq '0') {
    print $split_data[1], "\n";
}
[download]

Thanks moritz.... yeah I dint realized the string comparison.

Just wanted to point out a slight typo-ish thing. You left out this condition:

edit: oops, this was supposed to be in response to moritz's helpful comment.

Do you really need to use split? Why not match exactly what you want in the main loop?

#!/usr/bin/perl

use strict;
use warnings;

use feature 'say';

while (<DATA>) {
  # should you need it, the value is in $2, undef if not present
  say $1 if m{^ \s* \#define \s+ (\S+) (?:\s+ (0|1))? \s* $}x;
}

__DATA__
  #define thread 1
  #define flag
  #define code 0
  #define const (100/5)
  #define flag_condn 1
[download]

A couple of notes: if you are using an ancient (pre 5.10) perl, then don't use use feature 'say'; and say, instead use print $1, "\n";. The /x modifier allows nicer formating for the regexp: whitespace is ignored, comments are allowed (hence the \# here, since it's not a comment) and the regexp can be spread over several lines.

It looks like ++moritz has identified your problems.

You might find coding it like this, is a little more readable:

#!/usr/bin/env perl

use strict;
use warnings;

while (<DATA>) {
    my (undef, $def, $val) = split;
    print "$def\n" if ! $val or $val eq '1';
}

__DATA__
  #define thread 1
  #define flag
  #define code 0
  #define const (100/5)
  #define flag_condn 1
[download]

Output:

$ pm_define_extract.pl
thread
flag
code
flag_condn
[download]

Update: I changed the print line following moritz' comments below. It use to be:

    print "$def\n" if ! $val or $val =~ /^0|1$/;
[download]

print "$def\n" if ! $val or $val =~ /^0|1$/;

Note that !$val already covers the case where $val is 0.

Also /^0|1$/ is not what you might think it is. The OR | in regexes has a looser precedence than concatenation, which means the regex is the same as ^0 OR 1$, so it also matches strings like 0foo or bar1.

The correct way to write it is /^(0|1)$/, or if you don't want to create a capture, /^(?:0|1)$/.

Perl 6 - the future is here, just unevenly distributed

++ Thanks for spotting that. I've updated my node.

I wasn't aware of the precedence issue: thanks for the good explanation.

-- Ken