If you do not insist on using XML::TreeBuilder:

use strict;
use XML::Rules;
use Data::Dumper;

my $parser = XML::Rules->new(
    stripspaces => 7,
    rules => {
        'known-action,name' => 'content',
        'target' => sub {
            return $_[1]->{partner} => $_[1]->{'known-action'};
        },
        'targets' => 'no content',
        'drug' => 'pass no content'
    }
);

my $data = $parser->parse(\*DATA);
#print Dumper($data);

print "Name: $data->{name}\nType: $data->{type}\n";
while (my ($partner, $action) = each %{$data->{targets}}) {
  print "  $partner: $action\n";
}

__DATA__
<drug type="small molecule">
  <name>Goserelin</name>
  <targets>
      <target partner="1">
      <known-action>yes</known-action>
      </target>
      <target partner="2">
      <known-action>yes</known-action>
      </target>
      <target partner="3">
      <known-action>yes</known-action>
      </target>
  </targets>
</drug>
[download]

Or if you insist on having a separate array of partners and actions:

use strict;
use XML::Rules;
use Data::Dumper;

my $parser = XML::Rules->new(
    stripspaces => 7,
    rules => {
        'known-action,name' => 'content',
        'target' => sub {
            return '@partners' => $_[1]->{partner}, '@actions' => $_[1
+]->{'known-action'};
        },
        'targets' => 'pass no content',
        'drug' => 'pass no content'
    }
);

my $data = $parser->parse(\*DATA);
#print Dumper($data);

print "Name: $data->{name}\nType: $data->{type}\n";

print "Partners: ", join(', ', @{$data->{partners}}), "\n";
print "Actions: ", join(', ', @{$data->{actions}}), "\n";


__DATA__
<drug type="small molecule">
  <name>Goserelin</name>
  <targets>
      <target partner="1">
      <known-action>yes</known-action>
      </target>
      <target partner="2">
      <known-action>yes</known-action>
      </target>
      <target partner="3">
      <known-action>yes</known-action>
      </target>
  </targets>
</drug>
[download]

If the actual XML contains several <drug> tags, you should change its rule to "as array" or "by name" (uncomment the print Dumper($data); line to see what data structure you get in each case) or change it to a subroutine, that'll find the data in $_[1] in place of $data and may do whatever's necessary with that twig and forget the data that are no longer needed.