Rather than split'ing the line on spaces use a look-ahead to do it at a point followed by the text "address".

knoppix@Microknoppix:~$ perl -E '
> $line = qq{address 6433 main st address 6434 main st address 6435 ma
+in st\n};
> chomp $line;
> say for split m{(?=address)}, $line;'
address 6433 main st 
address 6434 main st 
address 6435 main st
knoppix@Microknoppix:~$
[download]

I hope this is helpful.

Update: A more complete solution catering for the two header lines and split'ing at a space that is followed by the text "address".

knoppix@Microknoppix:~$ perl -Mstrict -Mwarnings -E '
> open my $inFH, q{<}, \ <<EOF or die $!;
> This is the list of address
> here are the addreses
> address 6433 main st address 6434 main st address 6435 main st
> EOF
> 
> print scalar <$inFH> for 1 .. 2;
> my $line = <$inFH>;
> chomp $line;
> say for split m{\s+(?=address)}, $line;'
This is the list of address
here are the addreses
address 6433 main st
address 6434 main st
address 6435 main st
knoppix@Microknoppix:~$
[download]

You have a record separator: "address", it's just disguised as a record heading. Perl knows how to deal with alternate record separators (alternate to "\n", that is), as long as they can be represented as a literal string.

local $/ = q{address};    # Set record separator to 'address'.
open my $infile, '<', 'filename.txt' or die $!;
print "This is the list of addresses\n",
      "here are the addresses\n";
while( <$infile> ) {
    chomp;                # chomp removes the trailing record separato
+r.
    s/^\s+|\s+$//g;
    next unless length;
    print "address $_\n";
}
[download]

You might want to put your sample data into <code> tags, like your code, so we can tell for sure how it is formatted. But it appears that all your addresses are on a single line, and you want to break them into multiple lines. If that's the case, then <INFILE> will read in an entire line containing many addresses. That should match your regex (once), so the line should be split on spaces into words, and each word printed on its own line. What do you mean by "somehow it is not printing this part"? What is it printing?

Incidentally, there's no point in looping on $_ and then assigning it to a variable inside your loop, and it could (theoretically, at least) cause a bug. So don't do this:

while(<INFILE>){
  my $line = $_;
  # do stuff with $line

# but do one of these instead

while(<INFILE>){
  # do stuff with $_

# or

while(my $line = <INFILE>){
  # do stuff with $line
[download]

(Is there a popular Perl book or tutorial that shows that method? Seems like it shows up a lot here lately.)

Hi starface245,
from your code:

.....
 if ($line =~ /(address............)/) #13 dots for 13characters
 {
  my @values = split(' ', $line);


  foreach my $val (@values) {
    print "$val\n";    
 }    
 ......
[download]

address
6433
main
st
address
6434
main
st
address
6435
main
st
[download]

#!/usr/bin/perl
use warnings;
use strict;

my @values; 

while (<DATA>) {
    my ($line) = $_;
    chomp($line);
    if ( $line =~ m/^address/ ) {
        push @values, split( ' st ', $line );
    }
    else {
        print $line, $/;
    }
}

print $_, ' st', $/ foreach @values;

__DATA__
This is the list of address
here are the addreses
address 6433 main st address 6434 main st address 6435 main st
[download]

This is the list of address
here are the addreses
address 6433 main st
address 6434 main st
address 6435 main st
[download]

Will you never need to deal with address 6435 main ave or address 643 main st?

Update re reply: ... then the regex (still fragile, IMO because I don't believe in perfect data) might be more readably written as
      /=~ /(address.{13})/

No, the number of characters are always exact

Were you wanting something like the following for your data set?

use Modern::Perl;

while (<DATA>) {
    if ( !/\d/ ) {
        print;
    }
    else {
        say $1 while /(address.{13})/g;
    }
}

__DATA__
This is the list of address
here are the addreses
address 6433 main st address 6434 main st address 6435 main st
[download]

Output:

This is the list of address
here are the addreses
address 6433 main st
address 6434 main st
address 6435 main st
[download]

#!/usr/bin/perl -w
use strict;

my $str = "address 6433 main st address 6434 main st address 6435 main
+ st ";

# grep gets rid of the "" at the beginning.
# performace is slow, but effective
# there is more than one way to do this
# no fancy regex is required

my (@addresses) = grep{$_}split /address\s*/, $str;

my $line=1;
foreach (@addresses)
{
   print "address ", $line++, "  $_\n";
}

__END__
address 1  6433 main st 
address 2  6434 main st 
address 3  6435 main st
[download]

It prints:
address 6433 main st 
address 6434 main st 
address 6435 main st 

It does not print this part:
This is the list of address
here are the addreses

I want it to look exactly like this: 
This is the list of address
here are the addreses
address 6433 main st 
address 6434 main st 
address 6435 main st
[download]

Then I would describe the process as:

• for each line
  • if it starts with 'address', replace any space characters preceding the word 'address' with a newline
  • if not, pass the line through unchanged

So that would give me this code, which you can wrap in whatever input/output you need to do once you understand it:

while(<>){
  if(/^address/){
    s/ address/\naddress/g;
    print;
  } else {
    print;
  }
}
[download]

Aaron B.
Available for small or large Perl jobs; see my home node.

Did my reply here fail to meet your needs? I think I understood your question. Why are you repeating it?




Dave

Sorry Dave, but it did fail my needs. I needed someone to help fix my code, but not totally change it.