Anonymous Monk has asked for the wisdom of the Perl Monks concerning the following question: 

#!/usr/bin/perl -w
use strict;
use Tie::IxHash;
 
my %hash = %{ &fooFunc(); };
 
print "Compare this order to insertion order of fooFunc:\n\n";
foreach (keys %hash)
{
        print $hash{$_}."\n";
}
 
print "\n";
 
sub fooFunc
{
        tie my %h, "Tie::IxHash";
 
        $h{'donald'} = 'duck';
        $h{'calvin'} = 'human';
        $h{'hobbes'} = 'tiger';
        $h{'mickey'} = 'mouse';
        $h{'zorak'}  = 'bug';
 
        return \%h;
}

[download]

What I'm doing is having a hash which can give me out stuff in the same order I put it in (using Tie::IxHash). However, when I return a tied hash (to Tie::IxHash) from a subroutine, the hash won't remember the insertion order, but returns the keys apparently semirandomly, like an ordinary hash.

What am I doing wrong and how could I go round that? I'd like to have the hash returned from a subroutine, since it's used an arbitrary number of times.

The Tie::IxHash tied hash works properly inside the subroutine, but not when the reference is used. I've also tried to bless it again to Tie::IxHash but couldn't get it to work.

From the above example you see that in main the key/value pairs are not returned in the same order as put in, at least not for me. I'm using Perl 5.005_3 since our company hasn't made an official stance to take Perl 5.6 into use yet (plenty of scripts to check).

  • Comment on Reference to hash tied with Tie::IxHash doesn't remember insertion order
  • Download Code

Replies are listed 'Best First'.
Re (tilly) 1: Reference to hash tied with Tie::IxHash doesn't remember insertion order
by tilly (Archbishop) on Jul 19, 2001 at 17:16 UTC
    The problem is that in populating %hash you string the tied hash out into a list and then copy that data into the new hash. But now you have a hash %hash which isn't tied.

    The solution is to return the reference to the hash to a scalar like $h_ref and then do your lookups with: 

    foreach (keys %$h_ref) {
  print "$h_ref->{$_}\n";
}

    [download]
[reply]
[d/l]
follow-up
by Anonymous Monk on Jul 19, 2001 at 17:25 UTC

    Thank you everyone for answering.

    Yet another solution is to give a pre-tied hash reference to the function as another parameter. But I'll go with the suggestions given here :-)

[reply]

      Or just pass in a hash reference for the function to tie: 

      #!/usr/bin/perl -w
use strict;
 
fooFunc( \my %hash );
 
print "Compare this order to insertion order of fooFunc:\n\n";
foreach (keys %hash)
{
    print $hash{$_}."\n";
}
 
print "\n";
 
sub fooFunc
{
    my $h= shift;
    use Tie::IxHash;
    tie %$h, "Tie::IxHash";
 
    $h->{'donald'} = 'duck';
    $h->{'calvin'} = 'human';
    $h->{'hobbes'} = 'tiger';
    $h->{'mickey'} = 'mouse';
    $h->{'zorak'}  = 'bug';
}

      [download]

              - tye (but my friends call me "Tye")
[reply]
[d/l]
Re: Reference to hash tied with Tie::IxHash doesn't remember insertion order
by dragonchild (Archbishop) on Jul 19, 2001 at 17:16 UTC
    What you want to do is not use a standard hash, but instead use the Tie::IxHash OO methodology. It's not as clean, but it'll do what you want. 

    #!/usr/local/bin/perl -w
use strict;
use Tie::IxHash;

my $h = fooFunc();

print "This order now matches fooFunc()\n\n";

print $h->FETCH($_)."\n" for $h->Keys;

print "\n";

sub fooFunc {

    my $h = Tie::IxHash->new('donald' => 'duck');

    $h->Push('calvin' => 'human');
    $h->Push('hobbes' => 'tiger');
    $h->Push('mickey' => 'mouse');
    $h->Push('zorak'  => 'bug');

    return $h;
}

    [download]

    Review the perldoc for Tie::IxHash for more info.

[reply]
[d/l]

Back to Seekers of Perl Wisdom