From your initial shell process, you launch a perl process which launches another shell process which launches another perl process. No, this is not the best way to do things. Except for the system() function, you initially seemed to be on the right track. Here's how I would have tackled this:

#!/usr/bin/env perl

use strict;
use warnings;

my $infile = q{pm_read_part_file.in};
my $outfile = q{pm_read_part_file.out};
my $start = 3;
my $end = 5;

open my $in_fh, q{<}, $infile or die qq{Can't open $infile for reading
+: $!};
open my $out_fh, q{>}, $outfile or die qq{Can't open $outfile for writ
+ing: $!};

while (<$in_fh>) {
    next if $. < $start;
    last if $. > $end;
    print $out_fh $_;
}

close $in_fh;
close $out_fh;
[download]

Here's a sample run with file contents:

en@ganymede: ~/tmp
$ pm_read_part_file.pl
ken@ganymede: ~/tmp
$ cat pm_read_part_file.in
Line 1
Line 2
Line 3
Line 4
Line 5
Line 6
ken@ganymede: ~/tmp
$ cat pm_read_part_file.out
Line 3
Line 4
Line 5
ken@ganymede: ~/tmp
$
[download]

#!/usr/bin/perl -wn
BEGIN{
 use strict;
 my $outFile= "output.txt";
 my $inFile= "infile.txt";
 $main::start=17; # 'my' in this scope will result in uninitialized va
+lues outside the BEGIN{} block
 $main::end=30;
 close STDOUT; close STDIN;
 open STDIN,"<",$inFile || die $!;
 open STDOUT,">",$outFile || die $!;
}
print if $. >= $start && $. <= $end;
[download]

Any time I invoke anything on the OS via 'system' or backticks or any other way, I'd be worried that the program being called may not be in the path of the user running the script.

If you prefer running your one-liner as an OS command from inside a script, why not run it from a shell script then?

#!/usr/bin/sh

/usr/bin/perl -ne 'print if $. >=17 && $. <= 39' infile.txt >outfile.t
+xt
[download]

It seems someone taught you how to program outside of Perl before she taught you how to program inside of Perl. ;-)

Here's my riff on kcott's script…

#!/usr/bin/env perl

use strict;
use warnings;

use autodie qw( open close );
use English qw( -no_match_vars );

my $input_file  = 'input.txt';
my $output_file = 'output.txt';

my $start = 17;
my $end   = 30;

open my $input_fh,  '<', $input_file;
open my $output_fh, '>', $output_file;

LINE:
while (my $line = <$input_fh>) {
    next LINE if $INPUT_LINE_NUMBER < $start;
    last LINE if $INPUT_LINE_NUMBER > $end;

    print {$output_fh} $line;
}

close $input_fh;
close $output_fh;

exit 0;
[download]

And here's a greatly reduced version using <ARGV> and STDOUT instead of hardwiring file names inside the script…

#!/usr/bin/env perl

use warnings;

while (<>) {
    next if $. < 17;
    last if $. > 30;

    print;
}
[download]