The reason for this is that $rand (and, therefore, $firstcontact and $secondcontact) are always 0 because nothing ever gets passed to your subroutine which means you are effectively writing: $rand = int( rand() );

To start, I suggest adding:

use strict;
use warnings;
[download]

Also, take a look at perlsub to better understand how to pass values to subroutines and return what you want. While you are there, be sure to pay attention to the parts about scope since you typically want your variables in your subroutine to be isolated.

From the final print statement in the original code, it seems the intention is to mark a random sample of the population as infected, the size of this sample being input by the user as $answerinfect. If this interpretation is correct, the OP’s code does not work correctly, even setting aside the infinite loop, because each iteration of the outer for loop infects 2 distinct individuals, so the outcome is anywhere from $answerinfect to (2 * $answerinfect) infections (depending on the amount of overlap between loop iterations).

The following code incorporates the suggestions of aitap and frozenwithjoy, and insures that exactly $answerinfect individuals are infected. I have assumed (1) that the status field records infection, 0 for uninfected and 1 for infected; and (2) that the initial population contains no infected individuals.

#! perl
use strict;
use warnings;
use Data::Dumper;
use constant { WELL => 0,        SICK   => 1,    };

my  @pop = ( { name => 'Fred',   status => WELL, },
             { name => 'Wilma',  status => WELL, },
             { name => 'Barney', status => WELL, },
             { name => 'Betty',  status => WELL, }, );

(my $pop = scalar @pop) > 0                    or die "Empty populatio
+n\n";
print "How many random infections? (Enter a number between 1 and $pop)
+:\n";
chomp(my $answerinfect = <>);
($answerinfect > 0) && ($answerinfect <= $pop) or die "Invalid selecti
+on\n";

for (1 .. $answerinfect)
{
    for (my $new_infection = 0; !$new_infection;)
    {
        my $contact = int(rand($pop));

        if ($pop[$contact]{status} == WELL)
        {
            $pop[$contact]{status} = SICK;
            $new_infection         = 1;
        }
    }        
}

print Dumper(\@pop);
printf "You have infected %d %s: ", $answerinfect,
                                   ($answerinfect == 1) ? 'person' : '
+people';
print join(', ', sort map { $_->{name} } grep { $_->{status} == SICK }
+ @pop);
[download]

Typical output:

How many random infections? (Enter a number between 1 and 4):
2
$VAR1 = [
          {
            'status' => 0,
            'name' => 'Fred'
          },
          {
            'status' => 0,
            'name' => 'Wilma'
          },
          {
            'status' => 1,
            'name' => 'Barney'
          },
          {
            'status' => 1,
            'name' => 'Betty'
          }
        ];
You have infected 2 people: Barney, Betty
[download]

Some notes:

• The introduction of some elementary error checking helps prevent the generation of an infinite loop.
• Named constants improve readability and code clarity.
• The code to update a person from WELL to SICK has been moved from within the randompick_infect subroutine into the inner loop in the main code. As a consequence, randompick_infect’s remaining code is now short enough to be inlined. In any case, with the revised logic this subroutine would now be called only once anyway.
• The do {} while construct has been replaced with a for loop. Given Perl’s rules for lexical scoping (i.e., my variables), a for or while loop is often a simpler alternative to the do {} while construct. (And see perlfunc on the limitations of do loops in Perl.)

HTH,

You may want to chomp (my $answerinfect = <>); because otherwise it would contain "entered_answer\n". Does this give you any warnings?

What scope does the $j variable belong to? Did you try last instead of setting variable?

Infinite loop does not stop ...

infinite loop does not stop Wow. try re-reading that, it kinda is a little misleading. They are called infinite loops for a reason, the ain't supposed to stop!