in reply to Re^2: Changing every subroutine in many perl scripts
in thread Changing every subroutine in many perl scripts

Okay, I got it now, after going through the CPAN documentation a bit more.


use strict;
use warnings;
use PPI;

my $file = '/path/to/perl/script.pl';
my $Document = PPI::Document->new($file) or die "oops";

for my $sub ( @{ $Document->find('PPI::Statement::Sub') || [] } ) {
    unless ( $sub->forward ) {
        my @elements = $sub->children;

        for ( my $i = 0 ; $i < @elements ; $i++ ) {
            if ( ref $elements[$i] eq "PPI::Structure::Block" ) {
                $elements[$i]->start->add_content("my mars code");
            }
        }
    }
}

$Document->save($file.".new");

[download]

Replies are listed 'Best First'.
Re^4: Changing every subroutine in many perl scripts
by GrandFather (Saint) on Jul 25, 2012 at 22:24 UTC

    The loop would be better written:

    for my $sub (@{$Document->find('PPI::Statement::Sub') || []}) {
    next if $sub->forward;

    for my $child ($sub->children) {
        if (ref $child eq "PPI::Structure::Block") {
            $child->start->add_content("my mars code");
        }
    }
}

    [download]

    The next if ... saves a level of indentation and is easier to understand (at least for me) than an unless.

    Using a Perl style for loop in place of the C style for loop is easier to read, easier to understand, more compact and much less likely to get wrong.

    True laziness is hard work
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom