Use your regular expression to capture the hops count for China. Every time China is found, add the value captured to an accumulator for total number of hops. Increment a separate variable by one each time China is found. After the loop terminates, divide the total number of hops by the number of times China was found. That's your average.

If you need to keep track of more than just China, store each country as a hash key, and let that hash point to anonymous arrays containing a "found" count and a "hops" total for that country. After the primary loop ends, loop over the countries stored in the hash, and for each one, do the division as described above.

If you're having trouble with capturing the hops, you're almost there, and will be 100% there once you skim through, perlrequick and perlretut, looking for how to use capturing parenthesis.

I doubt you're having trouble with the math. And it seems that you understand how to store a value in variables. The += operator will come in handy for your hops accumulator.

If you end up going the hash of arrays route, you might need to look at perlreftut, and maybe perldsc.

It would have saved a lot of typing for me to just provide the solution, but then (a) you never ascend the learning curve, (b) you never gain the pleasure and confidence that come with figuring it out yourself, and (c) your client would owe me, not you.

I am having really a big trouble understanding and using hash, can you recommend a link or anything which explains with practical examples clearly.... Because arrays can work all the time i have found... Thanks

Have a look at Modern Perl by chromatic, pages 40–47. This book is available free online at http://modernperlbooks.com/books/modern_perl/.

Update: See also

• Perl variable types
• Data: Hashes (Associative Arrays)
• Beginning Perl by Simon Cozens, Chapter 3, “Lists and Hashes,” available free online at http://learn.perl.org/books/beginning-perl/
• Impatient Perl by Greg London, Section 2.3, “Hashes,” available free online at http://www.greglondon.com/iperl/index.htm
• QandASection: hashes
• Data Type: Hash.

HTH,

Athanasius <°(((>< contra mundum

Using the text file given in the above question or request, if I may give you a head up.

So is it possible that i can find the average

Yes, it is Possible!
Say, you want to find the average for country china only , you might do something like so:

use warnings;
use strict;

my $total_number_of_hops = 0;
my $number_of_matches    = 0;

while (<>) {
    chomp;
    if (/.+?-(china\s+?[0-9]+?\s+?hops?)/is) {
        ++$number_of_matches;
        my ( $country, $number_of_hops, $hop ) = split /\s+/, $1, 3;
        $total_number_of_hops += $number_of_hops;
    }
}

printf "Average Number of Hops for China is %.2f",
  $total_number_of_hops / $number_of_matches;
[download]

• change the regex in the if() to get all countries, including those that has space within their names,
• use data structure that get all the hops for each of the countries individually, then
• use either a for or a while loop or 'whichever', to get the countries and the average
• It's that simple ;-)

use warnings;
use strict;
use Data::Dumper;

my $country_hop_ref = {};

while (<>) {
    chomp;
    if (/.+?-(([a-z\s+]+?)\s+?([0-9]+?)\s+?hops?)/is) {
        push @{ $country_hop_ref->{$2} }, $3;
    }
}

print Dumper $country_hop_ref;
[download]

That is the head up, you need to find the average, yourself!!!

use strict;
use warnings;

use Locale::Country;
my @names = all_country_names();

# Better use Regexp::Trie
my $countries_re = do {
    local $" = q{|};
    qr/@{[map quotemeta, @names]}/i;
};

my %hash;
while (<>) {
    #if (/^.*?-([A-Z][A-Za-z\s\-]+[a-z])\s+(\d+)\s+hops?\b/is) {
    if (/^.*?-($countries_re)\s+(\d+)\s+hops?\b/is) {
        my ($country, $hops) = ($1, $2);
        $hash{$country} = {
                           sum => ($hash{$country}{sum} || 0) + $hops,
                           num => ++$hash{$country}{num}
                          };
    }
}

foreach my $key (sort keys %hash) {
    printf "$key avg: %.3f\n", $hash{$key}{sum} / $hash{$key}{num};
}

__END__
Australia avg: 30.000
China avg: 22.667
Czech Republic avg: 19.500
France avg: 30.000
Germany avg: 8.500
Japan avg: 18.000
Netherlands avg: 9.500
United Kingdom avg: 8.000
United States avg: 19.667
[download]