in reply to Archive::Zip - How to selectively copy files from one archive to another one?

We could better help you if you showed us the actual code you used with extractMember and addFile. When I use those, it works fine.

#!perl
use strict;
use warnings;
use Archive::Zip qw( :ERROR_CODES :CONSTANTS );

# Include actual filenames in the next three lines
my $oldfile = 'oldzip.zip';
my $newfile = 'newzip.zip';
my @wanted = ( 'perl.log', 'perld.log' ); 

my $oldzip = Archive::Zip->new();
$oldzip->read( $oldfile ) == AZ_OK or die 'read error';

my $newzip = Archive::Zip->new();

for my $file ( @wanted )
{
    $oldzip->extractMember( $file );
    $newzip->addFile( $file );
}

$newzip->writeToFileNamed( $newfile ) == AZ_OK or die 'error somewhere
+';

[download]
  • Comment on Re: Archive::Zip - How to selectively copy files from one archive to another one?
  • Download Code

Replies are listed 'Best First'.
Re^2: Archive::Zip - How to selectively copy files from one archive to another one?
by Gigabyte1907 (Initiate) on Aug 11, 2012 at 18:08 UTC

    Hello Mr. Muskrat and thanks for your reply.

    I didn't have the code that I tried and I tried so many things that I decided to start from scratch... ;-)

    Anyway I have tried your answer and first of all, it doesn't really answer the question because I was asking about selectively extract from one Zip and copy the files into another Zip. Which mean that I do not know yet what the file list is.

    Based on your example and trying to remember what I did before, here is the code that I came up with:

    use strict;
use Archive::Zip qw( :ERROR_CODES :CONSTANTS );

my $oldfile = 'oldzip.zip';
my $newfile = 'newzip.zip';

my $oldzip = Archive::Zip->new();
$oldzip->read($oldfile) == AZ_OK or die 'read error';

my $newzip = Archive::Zip->new();

# Getting the list of selected files
my @FileMembers123 = $oldzip->membersMatching("123.*\.xml");

foreach my $file (@FileMembers123)
{
    $oldzip->extractMember($file);
    $newzip->addFile($file);
}

$newzip->writeToFileNamed( $newfile ) == AZ_OK or die 'error somewhere
+';

    [download]

    When I try to execute this code, I have this error message:

    Can't call method "desiredCompressionLevel" on an undefined value at c:/perl/lib/Archive/Zip/Archive.pm line 249

    When I try to print the content of the array @FileMembers123, this is what I get:

    Archive::Zip::ZipFileMember=HASH(0x2f122f4)
    Archive::Zip::ZipFileMember=HASH(0x2f124c4)
    Archive::Zip::ZipFileMember=HASH(0x2f12694)
    Archive::Zip::ZipFileMember=HASH(0x2f12864)
    Archive::Zip::ZipFileMember=HASH(0x2f25a2c)
    Archive::Zip::ZipFileMember=HASH(0x2f2a804)
    etc...

    It seems that I cannot get the file names using the command my @FileMembers123 = $oldzip->membersMatching("123.*\.xml");.

    If I could generate the list of the files (using a matching pattern) in my old Zip without unzipping it, it would probably work.

    Thanks again!

[reply]
[d/l]
[select]

      It's all explained rather well in the docs. Archive::Zip

      addFile is expecting a filename not an Archive::Zip::ZipFileMember object. Try this instead:

      #!perl
use strict;
use warnings;
use Archive::Zip qw( :ERROR_CODES :CONSTANTS );

# Include actual filenames in the next two lines
my $oldfile = 'oldzip.zip';
my $newfile = 'newzip.zip';

my $oldzip = Archive::Zip->new();
$oldzip->read( $oldfile ) == AZ_OK or die 'read error';

print "$oldfile contains the following files:\n";
print "  $_\n" for $oldzip->memberNames();
print "\n";

my $newzip = Archive::Zip->new();

my @wanted = $oldzip->membersMatching( '123.*\.xml' );

for my $member ( @wanted )
{
    print "Extracting ", $member->fileName(), " from $oldfile and addi
+ng to $newfile\n";
    $oldzip->extractMember( $member );
    $newzip->addMember( $member );
}
print "\n";

$newzip->writeToFileNamed( $newfile ) == AZ_OK or die 'error somewhere
+';

print "$newfile contains the following files:\n";
print "  $_\n" for $newzip->memberNames();

__END__
# Sample output
oldzip.zip contains the following files:
  123a.xml
  123b.xml
  234c.xml

Extracting 123a.xml from oldzip.zip and adding to newzip.zip
Extracting 123b.xml from oldzip.zip and adding to newzip.zip

newzip.zip contains the following files:
  123a.xml
  123b.xml

      [download]
[reply]
[d/l]

In Section Seekers of Perl Wisdom