Is there a way of displaying it in the order it came in without using Tie::IxHash module. That is not on my system and will have to put in a ticket to have the module installed.

Do you have to have a ticket to install your code on your machine?

Copy & paste the code into your own source file; and tell the controlling powers that you've done so.

As you can see - the results are unordered.

That is the nature of hashes. The use-cases for hashes don't require (or benefit) from them being ordered. Humans like things ordered, but programs don't give a damn.

And if all you want to do is present the same information back to the users in the same form, just print the file to their screen.

But if you really must remember the order, just make a note of it as you go:

#! perl -slw
use strict;

my %ini;
my( $product, $feature );
while( <DATA> ) {
    chomp;
    if( /\s+(\S+)=(\S+)/ ) {
        $ini{ $product // die "Malformed ini at:$." }
            { $feature // 'none' }
            { $1 } = $2;
        push @{ $ini{ $product }{ $feature // 'none' }{ order } }, $1;
    }
    elsif( /^PROD/ ) {
        push @{ $ini{ $product }{ order } }, 'none'
            if $product and not exists $ini{ $product }{ order };
        $product = $_;
        push @{ $ini{ order } }, $product;
        undef $feature;
    }
    else {
        /^\s+(\S+)/ and $feature = $1;
        push @{ $ini{ $product }{order} }, $feature;
    }
}

for my $product ( @{ $ini{ order } } ) {
    print $product;
    for my $feature ( @{ $ini{ $product }{ order } } ) {
        print "\t", $feature if $feature ne 'none';
        for my $type ( @{ $ini{ $product }{ $feature }{ order } } ) {
            print "\t\t$type=$ini{ $product }{ $feature }{ $type }";
        }
    }
}

__DATA__
PRODUCT1
   FEATURE1_PRODUCT1
      PROPERTY1_FEATURE1_PRODUCT1=VALUE1
      PROPERTY2_FEATURE1_PRODUCT1=VALUE2
      PROPERTY3_FEATURE1_PRODUCT1=VALUE3
PRODUCT2
      PROPERTY1_PRODUCT2=VALUE1
      PROPERTY2_PRODUCT2=VALUE2
PRODUCT3
   FEATURE1_PRODUCT3
      PROPERTY1_FEATURE1_PRODUCT3=VALUE1
      PROPERTY2_FEATURE1_PRODUCT3=VALUE2
      PROPERTY3_FEATURE1_PRODUCT3=VALUE3
   FEATURE2_PRODUCT3
      PROPERTY1_FEATURE1_PRODUCT3=VALUE1
   FEATURE3_PRODUCT3
      PROPERTY1_FEATURE1_PRODUCT3=VALUE1
      PROPERTY2_FEATURE1_PRODUCT3=VALUE2
      PROPERTY3_FEATURE1_PRODUCT3=VALUE3
PRODUCT4
      PROPERTY1_PRODUCT4=VALUE1
      PROPERTY2_PRODUCT4=VALUE2
PRODUCT5
[download]

Produces:

[18:17:59.55] C:\test>junk44
PRODUCT1
        FEATURE1_PRODUCT1
                PROPERTY1_FEATURE1_PRODUCT1=VALUE1
                PROPERTY2_FEATURE1_PRODUCT1=VALUE2
                PROPERTY3_FEATURE1_PRODUCT1=VALUE3
PRODUCT2
                PROPERTY1_PRODUCT2=VALUE1
                PROPERTY2_PRODUCT2=VALUE2
PRODUCT3
        FEATURE1_PRODUCT3
                PROPERTY1_FEATURE1_PRODUCT3=VALUE1
                PROPERTY2_FEATURE1_PRODUCT3=VALUE2
                PROPERTY3_FEATURE1_PRODUCT3=VALUE3
        FEATURE2_PRODUCT3
                PROPERTY1_FEATURE1_PRODUCT3=VALUE1
        FEATURE3_PRODUCT3
                PROPERTY1_FEATURE1_PRODUCT3=VALUE1
                PROPERTY2_FEATURE1_PRODUCT3=VALUE2
                PROPERTY3_FEATURE1_PRODUCT3=VALUE3
PRODUCT4
                PROPERTY1_PRODUCT4=VALUE1
                PROPERTY2_PRODUCT4=VALUE2
PRODUCT5
[download]