Here's another option:

use Modern::Perl;
use Data::Dumper;

my @array = qw/1 A 2 B 3 C 4 D 5 E/;
my $i = 0;

say 'Before:';
say Dumper \@array;

@array = grep !($i++ % 2), @array;

say 'After:';
say Dumper \@array;
[download]

Outout:

Before:
$VAR1 = [
          '1',
          'A',
          '2',
          'B',
          '3',
          'C',
          '4',
          'D',
          '5',
          'E'
        ];

After:
$VAR1 = [
          '1',
          '2',
          '3',
          '4',
          '5'
        ];
[download]

This uses the modulo operator within grep to let only the even-numbered elements of the array pass.

Hope this helps!

Might your strings be numeric, or can you simply grep out non-digits?

@array = grep !/\D/, @array;
[download]

Otherwise, I'd grab every other like:

my $i;
@array = grep ++$i%2, @array;
[download]

Here is one way:

#! perl
use strict;
use warnings;
use Data::Dumper;

my @array = (1, 'Matthew',
             2, 'Mark',
             3, 'Luke',
             4, 'John',
             5);

my @copy = @array;
my @list;

while (@copy)
{
    push( @list, shift @copy );
    shift @copy;    # throw the string away
}

print Dumper(\@list);
[download]

Output:

$VAR1 = [
          1,
          2,
          3,
          4,
          5
        ];
[download]

HTH,

your problem could easily be solved with:

%hash=@array;
@ints = keys %hash;
@strs = values %hash;
[download]

for the second case (unique strings) use reverse

%hash= reverse @array;
@strs = keys %hash;
@ints = values %hash;
[download]

test in debugger:

  DB<103> %hash = reverse qw/1 A 2 B 3 C 4 D 5 E/
 => ("E", 5, "D", 4, "C", 3, "B", 2, "A", 1)
 
  DB<104> keys %hash
 => ("A", "C", "D", "B", "E")
 
  DB<105> values %hash
 => (1, 3, 4, 2, 5)
[download]