This is related to the Longest Repeated Substring Problem. According to the article I linked to, the problem can be solved in linear time after building a Suffix Tree. It turns out there's a module on CPAN that works with suffix trees: Tree::Suffix.

Tree::Suffix is a big pain to install. You have to visit http://www.icir.org/christian/libstree/, download and unpack its tarball, and then sudo ./configure. After it's installed you have to force the installation of Tree::Suffix: cpanm -f Tree::Suffix. I haven't taken the time to uncover what's wrong with it that causes some failures. But it seems to work once installed.

After that's all said and done, it becomes easy:

use Tree::Suffix;

my $string
    = 'The cat jumped over the dog. Smart cat! He jumped over the dog.
+ '
    . 'The cat jumped over the dog.';

my $tree = Tree::Suffix->new($string);

print "$_\n" for $tree->lrs;
[download]

The output...

The cat jumped over the dog.
[download]

$tree->lrs is a convenient alias to $tree->longest_repeated_substrings; you can use either method name.

If anyone knows of a better module for building suffix trees (one that installs cleanly), please follow-up with suggestions.

Interesting module and article. This is more what I was looking for! Thanks a lot, I'll look into it.

I'm inclined to use Lingua::EN::Sentence to get the sentences, since it's a well-developed module for that purpose. Given this, perhaps the following will help:

use Modern::Perl;
use Lingua::EN::Sentence qw( get_sentences );

my ( $LRS, %seen ) = '';
my $sentences = 'Mr. Cat jumped over the dog. Smart Mr. Cat! He jumped
+ over the dog. Mr. Cat jumped over the dog.';
map { $seen{$_}++ and length $_ > length $LRS and $LRS = $_ }
  @{ get_sentences($sentences) };
say $LRS;
[download]

Output:

Mr. Cat jumped over the dog.
[download]

Update: Modified some sentences to challenge Lingua::EN::Sentence.

Interesting module, I'll look into in, thank you.

You're most welcome, Jester!

You could try this:

#! perl -slw
use strict;

my $para = do{ local $/; <DATA> };
$para =~ tr[ \t\n][ ]s; ## normalise whitespace

my $longest = '';
length( $1 ) > length( $longest )
    and print '?', $longest = $1
    while $para =~ m[(.+)(?=.*?\1)]ig;

print $longest;

__DATA__
Ah, I am kind of embarrassed not to have thought of this.
I was so focused on look ahead, for some reason, but yeah,
this works. The thing is, I need to match more than one
sentence, potentially whole sections of texts can be
duplicated and I need to find them. I will try your solution
see how it goes. Thanks!I am kind of embarrassed not to have
thought of this for some reason, but yeah, this works. The
thing is, I need to match more than one sentence,
[download]

Outputs:

C:\test>junk24
?Ah,
?I am kind of embarrassed not to have thought of this
?for some reason, but yeah, this works. The thing is, I need to match 
+more than one sentence,
for some reason, but yeah, this works. The thing is, I need to match m
+ore than one sentence,
[download]

Remove the print '?', once your happy it is doing the right thing.

Something like this?

use strict;
use warnings;
my $text = 'The cat jumped over the dog. Smart cat! He jumped over the
+ dog. The cat jumped over the dog. Smart cat!';
my %seen;
my $longest = '';

while ($text =~ /\s*(.+?[!?.])/g) {
   $longest = $1  if $seen{$1}++ && length $1 > length $longest;
}
print $longest,$/;
[download]

Prints:

The cat jumped over the dog.
[download]

But it's a whole other challenge if you mean "phrase" and not (terminated) sentence.

Ah, I am kind of embarrassed not to have thought of this. I was so focused on look ahead, for some reason, but yeah, this works. The thing is, I need to match more than one sentence, potentially whole sections of texts can be duplicated and I need to find them. I will try your solution see how it goes. Thanks!

Oh, in fact this does not quite work. In that case, I would need it to print "The cat jumped over the dog." and "Smart cat!" as strings that are repeated.