Here is a step by step sort of thing I hope it helps decrypt it a bit ! :) Ill crunch it all into one thing too then.

# drawn out 
my @anon =  @{$account{'owners'}};
my %owner1 = %{$anon[0]};
my $name = $owner1{'name'};

print $name;

#####

# one line

print ${$account{'owners'}[0]}{'name'};
[download]

You have the following line in your script:

my $ownersRef = [ $owner1Ref, $owner2Ref ];
[download]

A two-element anonymous array is created, and $ownersRef is a reference to it. To get at the element 0 of this array, the arrow operator can be used to deference the array reference:

print $ownersRef->[0]
[download]

Output:

HASH(0x27ee58)
[download]

Element 0 in the anonymous array is a hash reference (and so is element 1). So, to get "Santa Claus" (sounds like a movie plot, doesn't it???!), another arrow operator can be used for dereferencing the hash reference:

print $ownersRef->[0]->{name};
                   ^      ^
                   |      |
                   |      + hash key for "Santa Claus"
                   |
                   + array element 0
[download]

Output:

Santa Claus
[download]

How would I print "Santa Claus" (name of owner1Ref) by accessing it through account?

print $account{owners}[0]{name};
[download]

You don't need the additional syntax shown in earlier replies: nested braces; dereferencing (->); quoting.

Here's my test:

$ perl -Mstrict -Mwarnings -le '
# Braces denote an anonymous hash
my $owner1Ref = {
    "name" => "Santa Claus",
    "DOB"  => "1882-12-25",
};

my $owner2Ref = {
    "name" => "Mickey Mouse",
    "DOB"  => "1928-11-18",
};

# Square brackets denote an anonymous array
my $ownersRef = [ $owner1Ref, $owner2Ref ];

my %account = (
    "number" => "12345678",
    "opened" => "2000-01-01",
    "owners" => $ownersRef,
);

print $account{owners}[0]{name};
'
Santa Claus
[download]

See also: perldsc - Perl Data Structures Cookbook

I think visually, so it helps to use Data::Dumper to get a visual display of what the data structure looks like:

print Dumper( $account{owners} );
[download]

Add this after your code and you get:

$VAR1 = [
          {
            'DOB' => '1882-12-25',
            'name' => 'Santa Claus'
          },
          {
            'DOB' => '1928-11-18',
            'name' => 'Mickey Mouse'
          }
        ];
[download]