use warnings;
use strict;
use Acme::Tools qw(avg);

my @nums;
while (<DATA>) {
    push @nums, (split)[3];
}
print avg(@nums), "\n";

__DATA__
a b c 3
d e f 4
h j k 5
[download]

See also:

• Acme::Tools
• split
• Slices

Without having seen it the input, the code that fits the problem description is:

perl -F'\t' -lanE'$sum += $F[3]; END { say $sum/$. }'
[download]

The input is a tab delimited file like:

chr    start    end    length
chr1   10       50      40
chr2    20      80      60
[download]

I want to get the average length of all lines.

In your OP, you show the following:

open (MYFILE, '148-N-pvalue0.01_peaks.xls');
#READ THROUGH THE FILE
   while (my $line = <MYFILE>)
   {
...
[download]

opening an Excel spread sheet this way will not give you access to the data you want. If you're are trying to parse an Excel spread sheet, consider using a module, like Spreadsheet::ParseExcel for the job. Otherwise, you can use "Save As..." within Excel to save the data as tab-delimited in a text file, e.g., "148-N-pvalue0.01_peaks.txt", which you can then open and process as above.

toolic shows how to obtain the last column's average, which includes using Acme::Tools. Importantly, two other pragmas begin the solution:

use warnings;
use strict;
[download]

Consider always beginning your scripts with these, as they'll preemptively catch any problematic areas in your scripts--likely saving you many headaches.

Arg, that's very similar to the other solutions but not so elegant. Well... another way to skin this cat

#!/usr/bin/perl
use strict; use warnings;
use List::Util qw(sum);

my @array = ();
while (<DATA>) {
   next if /start/;
   chomp;
   my (undef,undef,undef,$col4,undef) = split (/\s*/, $_,5);
   push (@array, $col4);
}

my $sum = sum(@array);    print $sum,"\/";
my $n = scalar(@array);   print $n,"\n";
print "average = ", $sum/$n,"\n";

__DATA__
chr    start    end    length foo
e r t 6 r
4 A 6 4 f
4 3 4 5 f
L 0 L 2 f
0 0 0 1 0
3 4 5 6 7
[download]

I like toolic's solution, but if you prefer not to use a module:

use strict;
use warnings;
my $sum;
my $count;
while (<DATA>) {
    my $length = (split)[3];
    next if $length eq 'length';
    $count++;
    $sum += $length;
}
my $average_length = $sum/$count;
print $average_length, "\n";
__DATA__
chr    start    end    length
chr1   10       50      40
chr2    20      80      60
[download]

perl -MList::Util=sum -E '<>; say sum( map{ (split /\t/)[-1] } <>);' f
+ile.tsv
[download]