in reply to Search array of file names in directory structure

Try using the following to create an alternation regex for your name rule:

my $regex = join '|', map "\Q$_\E?", @filelist;

my $find = File::Find::Rule
  ->file
  ->name(qr/^(?:$regex)$/)
  ->start( $dir );

while ( defined( my $html_document = $find->match ) ) {
    push @found_html, $html_document;
}

$f_count = scalar @found_html;

[download]

The generated regex:

1234567_3a_20101000\.html?|99877_b_20111111\.html?|99877_c_20111111\.h
+tml?|99877_d_20111111\.html?|99877_e_20111111\.html?|99877_uf_2011111
+1\.html?|1234567_g_20101000\.html?|99877_h_20111111\.html?|99877_i_20
+111111\.html?|99877_j_20111111\.html?|99877_k_20111111\.html?|99877_l
+l_20111111\.html?|1234567_pl_20101000\.html?|99877_qa_20111111\.html?
+|99877_rr_20111111\.html?|99877_sx_20111111\.html?|99877_xy_20111111\
+.html?|99877_nm_20111111\.html?

[download]

Since you've established a regex name rule, you don't need to check the results of $find->match, as it's using that rule.

Edit: Have updated the regex, based upon kennethk's comments.

Replies are listed 'Best First'.
Re^2: Search array of file names in directory structure
by kennethk (Abbot) on Oct 01, 2012 at 17:34 UTC
    If you are going for an autogenned regex off a fixed file list, why bother with the grouping? By the time you've gotten to the file extension, you've already passed the more rigorous constraint. Plus, yours can fail positive due to substring match and your filter doesn't allow for checking .htm files, as in the original regex. Simpler and more recyclable: 
    my $regex = do {
    my @escaped;
    push @escaped, quotemeta for @filelist;
    my $joined = join '|', @escaped;
    qr/^(?:$joined)$/;
};

    [download]
    or, if you like things done in 1 shot, 
    my $regex = '^(?:' . join('|', map quotemeta, @filelist) . ')$';

    [download]
    or, for the overly clever, my $regex = qr/^(?:@{[join '|', map quotemeta, @filelist]})$/;

    #11929 First ask yourself `How would I do this without a computer?' Then have the computer do it the same way.

[reply]
[d/l]
[select]

      Great comments! Actually, I completely missed the l? in the original regex. Unless I'm mistaken, your regex filter also doesn't allow for checking .htm files.

      Have updated my posting. Appreciate you bringing these issues to my attention.

[reply]
[d/l]
[select]

        It doesn't, but only insofar is it only checks the literals of the passed list. At some point, of course, all this becomes academic, since we don't actually know the entire use case; TIMTOWTDI.

        #11929 First ask yourself `How would I do this without a computer?' Then have the computer do it the same way.

[reply]
Re^2: Search array of file names in directory structure
by Anonymous Monk on Oct 02, 2012 at 15:41 UTC
    Hi, can you explain the Reg. Expression from this line?
    my $regex = join '|', map "\Q$_\E?", @filelist;

    [download]

    If you need to look for a particular pattern how would you alter this code; "\Q$_\E?"
[reply]
[d/l]
[select]

      Here's the line, explained a bit:

      my $regex = join '|', map "\Q$_\E?", @filelist;
                  ^         ^ ^ ^^
                  |         | | ||
                  |         | | |+ - Last character in file name optio
+nal, i.e., the "l" in html
                  |         | | + - End quote metacharacters
                  |         | + - The default scalar aliased to each @
+filelist element
                  |         + - Begin quote metacharacters (e.g., the 
+period)
                  + - Join each element with alternation ("or") charac
+ter

      [download]

      As shown, this results in the following:

      1234567_3a_20101000\.html?|99877_b_20111111\.html?|99877_c_20111111\.h
+tml? ...

      [download]

      This line builds a regex using the file names in @filelist. When passed to File::Find::Rule as the -name rule, only those files names which match the regex will be returned by File::Find::Rule, if any.

      If you want File::Find::Rule to look for a particular pattern, change the regex here:

      ->name(qr/^(?:$regex)$/)
          ^^^^^^^^^^^^

      [download]

      However, if you want to process the files returned by File::Find::Rule, you can do something like this:

      my @matchingFileNames = grep /pattern/, @found_html;

      [download]

      where "pattern" represents the regex that would 'filter' the elements of @found_html.

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom