squarez:

You do it basically the same way you're already doing. Just use a column counter that's set to 0 at the start of each row:

while (my @res = $sth->fetchrow_array()) {
   my $c=0;
   $worksheet->write($i, $c++, $_) for @res;
   $i++;
}
[download]

...roboticus

When your only tool is a hammer, all problems look like your thumb.

I had looked at it and yes I do need to increment the columns when I start to split the columns, but the issue is that the query returns a set that is only in one column, and I need to take that column, into a data array, then pull each part of the data array out, split those values amongst the columns, and trim the ( ). I see now that split cleans , for me. The issue now is taking the split and passing the split parts to different columns. So you have this :

while (my @res = $sth->fetchrow_array()) {
   my $c=0;
   $worksheet->write($i, $c++, $_) for @res;
   $i++;
}
[download]

That results in this:

COL ->    A        B        C        D        E        F
ROW -> 1 (x,y,..)
       2 (a,b,..)
       3 (q,w,..)
       4 (d,f,..)
          etc...
[download]

With my query results this only returns one column of data because all the columns for each row are consolidated in the first column from the result set. My perl script needs to rip that apart and allocate the contents of that first column to the other columns.

Also thank you for the help. I am currently thinking of:

while ($res[$o] = $sth->fetchrow_array()) {
    <code for splitting current array segment, and then printing the c
+orresponding splits into the next columns sequentially.>
}
[download]

I am thinking possibly another loop with an array to populate each rows values, then writing within that sub loop to each row column.

I get the funny feeling your 'first column' is just a string like this "(a, b, c, d)" (but I might be wrong, as I am new at this) If that is the case, removing the parentheses and then splitting on the comma will fix your issue:

my $set = $res[0];
#I use a lot of 'extra' variables to tell me what everything is

$set =~ s/[\(\)]//g;
#remove all parentheses

my @values = split(',', $set);
#now every value should have its own spot in the array
[download]

I hope this solves your problem.

Please ignore me if this is a stupid answer...

G'day squarez,

Welcome to the monastery.

I can't actually find a module called WriteExcel on CPAN. There's a lot with WriteExcel in the name: I'm going to guess you're using Spreadsheet::WriteExcel.

This module has a method called write_row() whose documentation has:

"... This is useful for converting the results of a database query into an Excel worksheet. ..."

You should be able to modify your code to something like (untested):

while (my @res = $sth->fetchrow_array()) {
    @res = map { defined ? $_ : '' } @res;
    $worksheet->write_row($i, 0, [@res]);
    $i++;
}
[download]

I also noted Excel::Writer::XLSX has a method with the same name which appears to work the same (from a coding perspective).

Even if you're using a different module, you may still find the technique applicable. If not, let us know what you are using.

I apologize, I am using the Spreadsheet::WriteExcel module. As I mentioned to roboticus above, the problem is splitting the column data, not fetching and writing from an array. I need to take each entry from the data array, split up that string by "," delineation, then pass those values to the sequential columns. Think of that first column I am returning as a compressed view of a table all in one column.

Thank you for the help :)

I think the confusion stems from (x,y,z,etc) which looks like an array; when, in fact, it's a string, i.e. '(x,y,z,etc)'.

Assuming I've got that right, this piece of code shows how to split the data. I'm still not entirely sure what you mean by "There are also times when there is no data": I've added 3 additional tests with no data between commas, between parentheses and between single-quotes.

#!/usr/bin/env perl

use strict;
use warnings;

use Data::Dumper;

my $res_re = qr{ \A [(] ( .* ) [)] \z }x;

my @all_res = (
    ['(x,y,z,etc)', 'maybe other stuff'],
    ['(x,y,z,etc,,abc,,,def)', 'maybe other stuff'],
    ['()', 'maybe other stuff'],
    ['', 'maybe other stuff'],
);

for (@all_res) {
    my @res = @$_;
    print Dumper \@res;
    $res[0] = '()' unless $res[0];

    my $res_wanted = [ split /,/ => ($res[0] =~ $res_re)[0] ];
    $res_wanted = [ '' ] unless @$res_wanted;
    print Dumper $res_wanted;
    print '-' x 60, "\n";
}
[download]

Here's the output:

$ pm_split_res_for_excel.pl
$VAR1 = [
          '(x,y,z,etc)',
          'maybe other stuff'
        ];
$VAR1 = [
          'x',
          'y',
          'z',
          'etc'
        ];
------------------------------------------------------------
$VAR1 = [
          '(x,y,z,etc,,abc,,,def)',
          'maybe other stuff'
        ];
$VAR1 = [
          'x',
          'y',
          'z',
          'etc',
          '',
          'abc',
          '',
          '',
          'def'
        ];
------------------------------------------------------------
$VAR1 = [
          '()',
          'maybe other stuff'
        ];
$VAR1 = [
          ''
        ];
------------------------------------------------------------
$VAR1 = [
          '',
          'maybe other stuff'
        ];
$VAR1 = [
          ''
        ];
------------------------------------------------------------
[download]

-- Ken