This works for me:

#!/usr/bin/perl
use warnings;
use strict;

open my $TEMPLATE, '<', 'rtr-template.txt' or die "Template: $!";
my @template = <$TEMPLATE>;

while (<>) {
    chomp;
    my ($location, $name, $lo0ip, $frameip, $framedlci, $eth0ip)
        = split (/,/);

    my $ofile_name = $name . ".txt";
    open my $OUT, '>',  $ofile_name or die "Output: $!";

    for my $line (@template) {
        $_ = $line;
        s/##location##/$location/;
        s/##rtrname##/$name/;
        s/##eth0-ip##/$eth0ip/;
        s/##loop0-ip##/$lo0ip/;
        s/##frame-ip##/$frameip/;
        s/##frame-DLCI##/$framedlci/;
        print {$OUT} $_;
   }
}
[download]

The important changes I made to your code:

• 3-argument version of open is used.
• Lexical filehandles are used ($FH instead of FH).
• I am using strict.
• The template file is not changing, so it is opened and read just once.
• chomp is used to remove the newline from $eth0ip.
• print is used instead of printf: using printf without a format string is useless.