Tied hashes are backed by objects. If you have a tied hash %foo then you can access the underlying object using tied(%foo). You can call methods on it like tied(%foo)->my_method(42).

If you have a tied hash, yes, it's also possible to bless a reference to that hash into a particular class. This may even be a different class to the one used to implement the tied behaviour.

And here's a quick example to show a hash tied to one class and blessed into another...

use v5.14;
use Test::More;

package MyClass 1.0 {
    sub new {
        my ($class, $hashref) = @_;
        bless $hashref => $class;
    }
    sub quux {
        return 'quuux';
    }
}

use Hash::DefaultValue; # it's on CPAN

tie my %hash, 'Hash::DefaultValue', 42;

ok(
    $hash{hello} == 42,
    'tie works properly',
);

my $object = MyClass->new(\%hash);

ok(
    $object->{world} == 42,
    'tie works properly, even when blessed',
);

ok(
    $object->isa('MyClass') && !$object->isa('Hash::DefaultValue'),
    'blessed into the proper class'
);

ok(
    tied(%$object)->isa('Hash::DefaultValue') && !tied(%$object)->isa(
+'MyClass'),
    'tied to the proper class'
);

ok(
    $object->quux eq 'quuux',
    'method calls on object work',
);

done_testing();
[download]