G'day Priti24,

Perl already provides the functionality you describe. So, unless you have a specific reason for re-inventing the wheel (which may be perfectly valid but isn't addressed in your post), you can use code like this to achieve what you're after.

#!/usr/bin/env perl

use strict;
use warnings;

my %ex = (
    37 => 'p', 41 => 't', 23 => 's', 52 => 'm', 44 => 'a', 65 => 'q',
    26 => 'd', 88 => 'o', 99 => 'g', 100 => 'l', 101 => 'f', 201 => 'i
+'
); 

print 'Enter the key you want to search for: ';
my $k = <>;
chomp $k;

if (exists $ex{$k}) {
    print "The key '$k' has the value: $ex{$k}\n";
}
else {
    print "The key '$k' doesn't exist.\n";
}
[download]

Here it is in action with the three keys you mention (37, 47 & 101):

$ pm_hash_search.pl
Enter the key you want to search for: 37
The key '37' has the value: p

$ pm_hash_search.pl
Enter the key you want to search for: 47
The key '47' doesn't exist.

$ pm_hash_search.pl
Enter the key you want to search for: 101
The key '101' has the value: f
[download]

Here's some of the things you could have done better in the code you provided:

• Let Perl tell you when you're doing something potentially problematic, or just plain wrong, with strict and warnings. See usage in my code.
• Declare your variables. my is used most often - see my %ex and my $k in my code. With no declarations, all your variables become global which has all sorts of implications and is basically a headache you don't need to have. (There are other ways to declare variables - see perlsub for details.)
• You call your subroutine with an argument (perlhash($k)) but don't read that argument in the subroutine code. In this instance, my $k = shift; would have been sufficient; for multiple arguments, use something like my ($arg1, ..., $argN) = @_; - see perlsub for details.
• It's easy to mistype, misread or miscount the exact number of arrayrefs in @buckets = ( [],[],[],[],[],[],[],[],[],[] );. You can use the x operator to avoid all three types of problems: @buckets = ([]) x 10; - see perlop for details.
• When you read user input (typed from the keyboard) you'll get all the keystrokes including the final return. Use chomp to remove this (as I did in my code).
• Your code would be easier to read if it was laid out a little better - perlstyle has some suggestions regarding this.

use strict;
use warnings;
use Data::Dumper;

my %ex = (
37 => "p" , 41 => "t",
23 => "s" , 52 => "m",
44 => "a" , 65 => "q",
26 => "d" , 88 => "o" , 
99 => "g" , 100 => "l" , 101 => "f" , 201 => "i"
); 
my @buckets = ( [],[],[],[],[],[],[],[],[],[] );
sub perlhash
{
  my $k = shift @_;
  my $hash = 0;
  $hash = ($k % 10);
return $hash;
}


while(my ($k , $v) = each(%ex)) {
  my $hash = perlhash($k);
  my $ch = $buckets[$hash];
  my $entry;
  # print Dumper $buckets[$hash];
  if(scalar @{$ch} == 0){
     $entry = {$k => $v};
  }else{
    $entry = $ch->[0];
    $entry->{$k} = $v ;
    next;
  }
   push @$ch , $entry;
}
print Dumper \@buckets;

print "enter a key u want to search";
chomp(my $k = <STDIN>);
my $h = perlhash($k);
print "The Key in Slot $h is " .  join (",",keys (%{$buckets[$h][0]}) 
+) . "\n" ;
[download]