G'day Roboz,

Firstly, the data structure you present is invalid. In the code below, I've added a closing brace to 'Mineral' => { .... Also, you show $Var1 as being a reference to a hashref: I don't know if that's correct or another typo - the following code assumes it is correct.

This code shows how you might go about achieving what you're after. I'll leave you to make adjustments for whatever typos may exist.

#!/usr/bin/env perl

use strict;
use warnings;

my $SOAPresult = \{
     'Thing' => [
            {
             'Animal' => {
                 'ThingName' => 'Dog',
                 'ThingID' => '123'
                 }
            },
            {
             'Veg' => {
                  'ThingName' => 'Carrot',
                  'ThingID' => '42'
                    }
            },
            {
            'Mineral' => {
                 'ThingName' => 'Talc',
                 'ThingID' => '007'
                 }
            }
           ]
    };

my $SOAPresult_deref = $$SOAPresult;

my @types = qw{Animal Veg Mineral};

for my $type (@types) {
    foreach my $e ( @{ $SOAPresult_deref->{Thing} } ) {
        next unless exists $e->{$type};
        print "Wildcard = $type\n";
        print "$e->{$type}{ThingName}\n";
    }
}
[download]

Output:

$ pm_ref_var_access.pl
Wildcard = Animal
Dog
Wildcard = Veg
Carrot
Wildcard = Mineral
Talc
[download]