I am referring to the fact that, as documented in perlsub, calling &foo shares @_ with the current package. Calling it with parentheses gives it its own argument list. The following demo script may give you an idea what this means: 
#! /usr/bin/perl
use strict;
use vars qw($indent);

$indent = '';
print "Here is how things go without an &\n";
demo_no_amp(1..5);
<STDIN>;
print "Here is how they go with an &\n";
demo_with_amp(1..5);
<STDIN>;
print "And with explicit argument passing\n";
demo_explicit_args(1..5);
<STDIN>;
print "Done\n";

sub demo_no_amp {
  local $indent = $indent . "  ";
  while (@_) {
    my $arg = shift;
    print $indent, "Without &, '$arg'\n";
    demo_no_amp();
  }
}

sub demo_with_amp {
  local $indent = $indent . "  ";
  while (@_) {
    my $arg = shift;
    print $indent, "With &, '$arg'\n";
    &demo_with_amp;
  }
}

sub demo_explicit_args {
  local $indent = $indent . "  ";
  while (@_) {
    my $arg = shift;
    print $indent, "With explicit args, '$arg'\n";
    demo_explicit_args(@_);
  }
}

[download]
Puzzle out why those three cases are so different and you will understand why I think the second one is dangerous.

In reply to Re (tilly) 4: optimized switch case by tilly
in thread optimized switch case by screamingeagle

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.