$ cat 1028644.pl 
#!/usr/bin/perl
use strict;
use warnings;

my $nfshashofhashes = {
    "bigstorderv_mpt" => {
        "%export_name" => "/bb/bigstor/derv",
        "%filer_device" => "nydevnfs_derv",
        "%filer_volume" => "/vol/derv",
    },
    "bigstormtg_mpt" => {
        "%export_name" => "/bb/bigstor/mtgmodel",
        "%filer_device" => {
            "\@ridge" => "njdevnfs_mtge",
            "\@west" => "nydevnfs_mtge"
        },
        "%filer_volume" => "/vol/mtge",
    },
    "build10_mpt" => {
        "%export_name" => "/bb/source",
        "%filer_device" => {
            "\@ridge" => "rnap7751-s",
            "\@west" => "nydevnfs_sunbbsource"
        },
        "%filer_volume" => {
            "\@ridge" => "/vol/sunbbsource_c",
            "\@west" => "/vol/sunbbsource"
        }
    },
    "build11_mpt" => {
        "%export_name" => "/bb/source",
        "%filer_device" => {
            "fridge" => "rnap7751-s",
            "\@west" => "nydevnfs_sunbbsource",
        },
        "%filer_volume" => {
            "\@ridge" => "/vol/sunbbsource_c",
            "\@west" => "/vol/sunbbsource",
            "qwest" => "/vol/sunquirks",
        }
    },
};

while ( my ($MPT, $rMPT) = each %{$nfshashofhashes} ) {
    die "MPT<$MPT> NOT A HASH!\n" unless ref $rMPT eq 'HASH';
    die "MPT<$MPT> WRONG STRUCTURE!\n" unless exists $rMPT->{'%export_name'};
    
    my $EXP = $rMPT->{'%export_name'};

    # Set default value and hash ref for devices
    my ($rFILDEV, $DEVDFLT, $t);
    $t = $rMPT->{'%filer_device'};
    if (ref $t eq 'HASH') { $rFILDEV = $t;  $DEVDFLT = '????'; }
    else                  { $rFILDEV = { }; $DEVDFLT = $t;     }

    # Same for volumes
    my ($rFILVOL, $VOLDFLT);
    $t = $rMPT->{'%filer_volume'};
    if (ref $t eq 'HASH') { $rFILVOL = $t;  $VOLDFLT = '????'; }
    else                  { $rFILVOL = { }; $VOLDFLT = $t;     }

    # Match up the VOL and DEV entries in the hash.  Missing values for
    # DEV and VOL will be filled in with the DFLT values as needed.
    my %MATCHUP;
    $MATCHUP{$_}{VOL} = $rFILVOL->{$_} for keys %$rFILVOL;
    $MATCHUP{$_}{DEV} = $rFILDEV->{$_} for keys %$rFILDEV;

    # If both were scalars, MATCHUP is empty, so make a single matching record
    $MATCHUP{'BAR'} = { DEV=>$DEVDFLT, VOL=>$VOLDFLT } if ! keys %MATCHUP;

    # And our final results...
    for (keys %MATCHUP) {
        my $DEV = $MATCHUP{$_}{DEV} // $DEVDFLT;
        my $VOL = $MATCHUP{$_}{VOL} // $VOLDFLT;
        printf "%-20.20s %-20.20s %-20.20s %-20.20s\n",
               $MPT, $DEV, $VOL, $EXP;
    }
}

$ perl 1028644.pl
bigstorderv_mpt      nydevnfs_derv        /vol/derv            /bb/bigstor/derv    
build11_mpt          ????                 /vol/sunbbsource_c   /bb/source          
build11_mpt          rnap7751-s           ????                 /bb/source          
build11_mpt          ????                 /vol/sunquirks       /bb/source          
build11_mpt          nydevnfs_sunbbsource /vol/sunbbsource     /bb/source          
build10_mpt          rnap7751-s           /vol/sunbbsource_c   /bb/source          
build10_mpt          nydevnfs_sunbbsource /vol/sunbbsource     /bb/source          
bigstormtg_mpt       njdevnfs_mtge        /vol/mtge            /bb/bigstor/mtgmodel
bigstormtg_mpt       nydevnfs_mtge        /vol/mtge            /bb/bigstor/mtgmodel