Hello ravi45722,

I see two problems. First, print takes a list as its argument; or, putting that round the other way, print imposes list context on its argument(s). So

print <MYFILE>;
[download]

reads in the whole of the rest of the file (after the first line, which was already read in via the <MYFILE> in the while condition) and prints that on the first iteration of the loop.

Second, the line:

$data = join "", <MYFILE>;
[download]

does nothing, because the MYFILE filehandle is already pointing to the end of the file by the time it reaches this line. But if you were actually printing just the line already read in the while condition, the join would itself eat up the rest of the file, because it too imposes list context on its argument(s).

I think you’re looking for something like this, which uses concatenation in place of join:

use strict;
use warnings;

my $data;

while (<DATA>)
{
    print;
    $data .= $_;
}

print $data, "\n";

__DATA__
1st line
2nd line
3rd line
4th line

End of file
[download]

Output:

17:08 >perl 1355_SoPW.pl
1st line
2nd line
3rd line
4th line

End of file
1st line
2nd line
3rd line
4th line

End of file


17:08 >
[download]

Note: I’ve taken out the call to chomp; why remove the newline if you want to put it back again when printing and concatenating?

Hope that helps,

Your code is highly confused. There only is one instance of the MYFILE filehandle and the flow is as follows:

1. while(<MYFILE>)... reads one line from the file into $_
2. print <MYFILE> reads all remaining lines from MYFILE and prints them
3. $data = join "", <MYFILE> assigns the empty string to $data because MYFILE is at the end of the file now.

Maybe you can take a step back and explain why you are sprinkling various attempts to read from MYFILE over your code and what your real goal is?

Thanks for reply. I want to do exactly what Athanasius did. From this I learn How  while<MYDATA> &  print <MYDATA> works.

Others have pointed out some of the places where you have gone wrong in your original code. Here, I'd like to point out a recommended method from the FAQ.

If, for some odd reason, you really want to see the whole file at once rather than processing line-by-line, you can slurp it in (as long as you can fit the whole thing in memory!):

        open my $in,  '<',  $file      or die "Can't read old file: $!
+"
        open my $out, '>', "$file.new" or die "Can't write new file: $
+!";
        my $content = do { local $/; <$in> }; # slurp!
            # do your magic here
        print $out $content;
[download]

There really is lots of good stuff in the FAQ and if you will be doing any work with files at all, then FAQ 5 (linked above) will serve you well. Good luck.

Update: Hah! Brother Athanasius is nimbler of finger (not to mention grey matter) ...

As Corion points out, <MYFILE> is a filehandle from which you read and process one line at a time; it doesn't represent a line itself. A corrected version of your code is below.

[00:28][nick:~/monks]$ cat 1139778.txt
foo
bar
baz
qux
[download]

#!/usr/bin/perl
use strict;
use warnings;

# Don't hard-code filenames in logic code
my $file = '1139778.txt';

# Use the three-argument form of open() ...
open( my $MYFILE, '<', $file )   
  or die "Failed to open $file: $!\n";     # ... and always check for 
+success

# Use parentheses to show we want the whole list of lines
my $data = join '', (<$MYFILE>); 
print "Using \$data:\n$data\n\n";

# Go back to the beginning of the file
seek $MYFILE, 0, 0;

# No parentheses so we get one line at a time
print "Using \$line:\n";
while ( my $line = <$MYFILE> )  {
  # chomp; # No need to chomp if you are printing the file out again
  print $line;
}

close $MYFILE or die "Failed to close $file: $!\n";

__END__
[download]

[00:29][nick:~/monks]$ perl 1139778.pl
Using $data:
foo
bar
baz
qux


Using $line:
foo
bar
baz
qux
[download]

Hope this helps! Make sure you understand it all before you continue :-)

Heres another way :)

use strict;
use warnings;

#using three argument for open();
open ( my $output, '>', 'output' ) or die "cannot open file for writin
+g -$!";

#read and print all on one line ;)
print ( $output $_ ) while(<DATA>);

__DATA__
1st line
2nd line
3rd line
4th line

End of file
[download]

seems nobody proposed it so here is a way to do it

Read more... redundant post (449 Bytes)

seems nobody proposed it so here is a way to do it

perlintro and Modern Perl both discuss this

They also avoid a loop to slurp a file

use strict;
use warnings;
use Slurp;
my $data = slurp("/root/prac/packages/test.txt");
print $data;
[download]

:D A review of this module Slurp