my $one_but_false = OneButFalse->new();
print "value = $one_but_false\n";
print "truth = ", ($one_but_false ? "true\n" : "false\n");

package OneButFalse;
use overload '0+'   => sub {1};
use overload 'bool' => sub {0};
use overload fallback => 1;

sub new {
    my ($pkg) = @_;
    bless {}, $pkg;
}
[download]

-Blake

Another way is to use a dualvar() (from Scalar::Util) for such a purpose:

    use Scalar::Util qw/dualvar/;
    my $x = dualvar(1,"0");

    $y = $x + 41;
    print "$y\n"; # 42

    print "Str \$x: $x\n";
    print "Num \$x: ", $x + 0, "\n";

    if($x + 0){print "\$x + 0 is true\n"}
    unless($x){print "\$x is false\n"}
    __END__

    prints:
        42
        Str $x: 0
        Num $x: 1
        $x + 0 is true
        $x is false
[download]

I'm not sure why you would want a "1 but false" return value. The "0 but true" value is perl sugar for those cases where the underlying library returned 0 for true values and -1 for errors (ioct, fcntl, shmctl, etc). About the only place I've seen 1 be a "false" value is not for API calls but for exit statuses and then there's normally a range of positive exit values that indicate what the failure is (and 0 would be normal exit).

-derby