Without knowing what you are doing, saying that your 'trick' is or is not a correct way is next to impossible. If you want to keep the old contents, you have to make a copy. If you want to work with a reference to the array, you have to account for the fact that those contents can be altered.

my $p = \@a;
[download]

Now $p is a reference to @a. You can change the contents of @a via $p.

my $p = [@a];
[download]

$p is still a reference, but a reference to an anonymous array that contains the contents of @a. You can change the contents of $p, but that will not affect @a (as long as @a didn't contain any references ... we won't go there). You could also copy @a like so:

my @p = @a;
[download]

Instead of merely printing the contents out, i find using Data::Dumper to be much more helpful:

use strict;
use warnings;
use Data::Dumper;

my @a       = (1,2,3,4);
my @copy    = @a;
my $ref     = \@a;
my $refcopy = [@a];

@a = ();

print "orginal: ",    Dumper \@a;
print "array copy: ", Dumper \@copy;
print "reference: ",  Dumper $ref;
print "ref copy: ",   Dumper $refcopy;
[download]

UPDATE:
This is Perl, so instead of using the cluttered:

foreach (@{$p}) { print "element $_\n"; }
[download]

use the more readable (IMHO at least):

print "element $_\n" for @$p;
[download]

Have fun. :)

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)