File::Basename, it's in the core.

use File::Basename;
my @suffixes = qw/.pl .plx .pm/;
while (<>) {
    print basename( $_, @suffixes), $/;
}
[download]

Here goes...

my $string = '/whatever/filepath/and/name.dat';
my $filename;
if ( $string =~ m#/([^/]+)$# ) {
    $filename = $1;
    print $filename, "\n";
}
[download]

The regexp translated: Start by using 'm##' as the regexp delimiter instead of the more traditional m//, so that you don't have to escape the '/' character within the expresssion. Next, match the last '/' character in the string, then capture all of the rest of the characters that are not '/' through the end of the string.

This assumes that you're on an OS where path levels are delimited with '/'. You'll have to modify it if '\' is your delimiter of choice. This also assumes that there is at least one '/' in the path. ...so many assumptions, the module is probably a safer way of handling it.

my $fullpath = "/blah/blah/blah/blah/file1.pl";
my ($filename) = $fullpath =~ m!([^/]+$)!;
print "$filename\n";
[download]

#!/usr/bin/perl
m!([^/]*)$! and print "$1" while (<DATA>);
__DATA__
/blah/blah/blah/blah/file1.pl
/blah/blah/file2.pl
/blah/blah/blah/blah/blah/blah/blah/file3.pl
[download]

You could try something like this:

while(<DATA>) {
  if($_ =~ m/\/([\w\d\.]+)$/) {
     print "$1\n";
  }
}

__DATA__
/blah/blah/blah/blah/file1.pl
/blah/blah/file2.pl
/blah/blah/blah/blah/blah/blah/blah/file3.pl
[download]

This will result in the desired output.

All code is usually tested, but rarely trusted.

You said it (so I'm just repeating what you said ;^).

m/\/([\w\d\.]+)$/
[download]

Remember that "\w" represents alphanumerics and underscore -- no need to add "\d" to a character class when "\w" is already there.

This will result in the desired output.

... for the three examples provided, but not for file names that contain dashes, plus-signs, tildes, colons, ... Better not to try to match the file name content (since you don't need to).