#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };


my %ops = map eval "'$_' => sub { \$_[0] $_ \$_[1] }",
          qw( + - * / );


sub show {
    my ($x, $op, $y) = @{ $_[0] }[ 1 .. 3 ];
    return join q(),
           '(', $#$x ? show($x) : $x->[0],
           $op, $#$y ? show($y) : $y->[0], ')'
}


my %shown;
sub num {
    my ($result, @nums) = @_;
    if (1 == @nums) {
        if ($result == $nums[0][0]) {
            my $r = show($nums[0]);
            say $r unless $shown{$r};
            $shown{$r} = 1;
        }
        return
    }

    for my $i (0 .. $#nums - 1) {
        for my $j ($i + 1 .. $#nums) {
            for my $op (keys %ops) {
                my @couples = ([ $i, $j ]);
                push @couples, [ $j, $i ] if $op !~ /[+*]/;
                for my $couple (@couples) {
                    my ($x, $y) = @$couple;
                    next if '/' eq $op && 0 == $nums[$y][0];

                    my $r = $ops{$op}->(map $_->[0], @nums[ $x, $y ]);
                    num($result,
                        [ $r, $nums[$x], $op, $nums[$y] ],
                        @nums[grep $_ != $x && $_ != $y, 0 .. $#nums])
+;
                }
            }
        }
    }
}


num(17, map [$_], 2, 5, 6, 6);
[download]

Update: Bugfix: x-y and x/y were not tested for y-x and y/x.

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]