Hey, Monks, I love your show. Long-time reader, first time meditator.

From time to time, the need to match things not preceded by a pattern rears its head, and the natural tool for that is negative lookbehind. But if the pattern is variable-length, Perl's regex engine can't handle it. This limitation has, at times, resulted in bruised foreheads.

Here are a couple of recipes for working around that limitation. They're not pretty, but they should be plug-and-play.

Matching

# capture all two\d that are not preceded by fo+
$_ = 'footwo1 bootwo2 ftwo3 fotwo4';
$not = qr/fo+/;
$want = qr/two\d/;
print "Got $1\n" while /\G(?:(?!$not?$want).|$not$want)*($want)/g;
[download]

You define variables for what you want and what you don't want to precede it, and just use the pattern as it appears above.

Substituting

Substituting is similar, but because it's not real lookbehind, you have to avoid throwing away the lead-up part of the pattern. Let's say we want to replace all $want (where not preceded by $not) with X. You can capture the lead-up and re-insert it:

s/\G((?:(?!$not?$want).|$not$want)*)($want)/$1X/g;
[download]

Or you can match and substitute separately:

s/\G$want/X/ while /\G(?:(?!$not?$want).|$not$want)*(?=$want)/g;
[download]

If you want to do a single, rather than global replacement, change the while to an if. Leave the /g on the match -- it is necessary for setting the \G marker.

Note: Regexp::Keep would be very handy here, but this blew up for me:

s/\G((?:(?!$not?$want).|$not$want)*)\K($want)/X/g;
# yielded
Eval-group not allowed at runtime, use re 'eval' in regex m/\G((?:(?!(
+?-xism:fo+)?(?-xism:two\d)).|(?-xism:fo+)(?-xism:two\d))*)(?{Regexp::
+Keep::KEEP})((?-xism:two\d))/ at try2.pl line 9.
[download]