some untested pseudo-code ;) to get you started...

my %monks_by_level;

for my $monk ( @array_of_monks )
{
  my $level = $monk->level(); # or ->{level} or whatever...
  push @{ $monks_by_level{$level} }, $monk;
}

for my $level ( keys %monks_by_level )
{
  print "doing $level...\";
  callToPrayer( $monks_by_level{$level} );
}

sub callToPrayer
{
  my ($monks) = @_;

  for my $monk ( @$monks )
  {
    print "$monk->name() here!\n";
  }
}
[download]

Thanks, edan, that did the trick.

However, I don't quite get the bit

@{ $monks_by_level{$level} }

I understand this to mean that the $monks_by_level{$level} is the value of the hash for the key $level and that the @{ ... } around it automagically makes this value an array. Is this right?

loris

You're right, you just need a bit of terminology thrown in there. $monks_by_level{$level} is an array reference (see perlref for details) and @{ } is how we dereference an array reference, so that we can use it as an array. You could also dereference individual scalars in the array using syntax such as $monks_by_level{$level}[0].

--
edan

my (@monks);
while (<DATA>) {
    chomp; split(/ /);
    push(@{$monks[$_[1]]}, $_[0]);
}
mysub($_) for @monks;
sub mysub { print join(' ', sort(@$_)) . "\n"; }

__DATA__
monk1 2
monk2 5
monk3 8
monk4 4
monk5 1
monk6 5
monk7 3
monk8 7
monk9 7
[download]

my (@monks);
while (<DATA>) {
    chomp; split(/ /);
    $monks[$_[1]]{$_[0]} = ();
}
mysub($_) for @monks;
sub mysub { print join(' ', sort(keys %$_)) . "\n"; }

__DATA__
monk1 2
monk2 5
monk3 8
monk4 4
monk5 1
monk6 5
monk7 3
monk8 7
monk9 7
[download]

As you've received excellent answers above, this is a general comment. You're basically asking if you can drive a car without a rearview mirror. Well, yes, you can. But, it's a really dumb way to drive a car.

References are an integral part of Perl5, and should be treated as another tool in your toolbox, not as something to be feared and shunned. They are the way to create multi-level data structures¹. Period.

The Perl Cookbook generally has the best-of-breed way of doing task XYZ. It's the reason it's the cookbook. So, I'd trust it.

Now, I'm not saying "Don't question the wisdom", by any means. But, for most questions, you'll get the answer "The wisdom is right." *grins*

1. Well, there are other ways, but you really don't want to go there. References were put into the language for a really darn good reason. Globbing your data structures a la Perl4 just sucks.

I'd do something like:

my @monks = ...;  # Array of Monk objects, with a level method.
my %monks_by_level;
push(@{$monks_by_level {$_->level()}}, $_) for @monks;
while (my ($level, $monks) = each(%monks_by_level)) {
    callToPrayer($monks)
}
[download]

If you settle for passing in a list (and hence, losing any reference (no pun intended) to an array), you can do it "without references" (well, the objects you start out with are references) - if you know which levels there are (but you could find out by making another pass):

foreach my $level (1 .. 10) {
    callToPrayer(grep($_->level() == $level, @monks));
}
[download]