Use a negative width to left-justify. For example,
"%5s" means pad to 5 characters, right-justified.
"%-5s" means pad to 5 characters, left-justified.

The following are not the most compact solutions, but they are probably the most readable. Don't forget that programs should be written for those who maintain them.

Untransposed:

use strict;
use warnings;

use List::Util qw( max );
use POSIX      qw( ceil );

my @a = qw(un deux trois quatre jedan dva tritcheteri one two three);
my $cols = 4;

my $width = (max map length, @a) + 1;
my $rows = ceil(@a / $cols);

for my $r (0..$rows-1) {
   for my $c (0..$cols-1) {
      next if (my $i = $r * $cols + $c) > $#a;
      printf('%-*s', $width, $a[$i]);
   }
   print("\n");
}
[download]

Transposed:

use strict;
use warnings;

use List::Util qw( max );
use POSIX      qw( ceil );

my @a = qw(un deux trois quatre jedan dva tritcheteri one two three);
my $cols = 3;

my $width = (max map length, @a) + 1;
my $rows = ceil(@a / $cols);

for my $r (0..$rows-1) {
   for my $c (0..$cols-1) {
      next if (my $i = $r + $c * $rows) > $#a;
      printf('%-*s', $width, $a[$i]);
   }
   print("\n");
}
[download]

Now, wouldn't it be nice if each column was as narrow as possible? There's gotta be a module to do that on CPAN, but I didn't find one quickly.

Update: I had to leave before I could finish writting my entire node. Here's the rest.

Update: Fixed a bug in "Transposed". Thanks to jhourcle for pointing it out.

Secondly, I want the array printed or displayed in columns as "tight" as possible and _justified left_. I don't manage justifying left with sprintf(). Let's choose 4 columns. Knowing $max, the shortest I manage is:

Okay, let's assume we know $max (see ikegami's response) and $col:

use POSIX qw(ceil);

my $rows = ceil( scalar @a / $col );
for ( my $i = 0; $i < $rows; $i++ ) {
   printf( ("%-${max}s " x $col)."\n", map { defined $_ ? $_ : '' } 
      @a[($i*$col)..(($i*$col)+($col-1))] );
}

# transposed
$rows = ceil (scalar @a / $col );
for ( my $i = 0; $i < $rows; $i++ ) {
  printf( ("%-${max}s " x $col)."\n", map { defined $_ ? $_ : '' }
    @a[ map { $i+($_*$rows) } (0..$col-1) ] );
}
[download]

Of course -- it won't fill the width when transposed -- it fills height first. It'll also extend the end of your array, because of the way I'm messing with it, so you'll want to make a copy first (which isn't too bad if you're working in a subroutine)

Personally, I'd just like the '#' feature in MudOS's version of (s)printf (you tell it a number of characters wide, and an array, and it generates a listing to fit)

I don't manage justifying left with sprintf().

I take that to mean you just haven't learned yet how this is done; ikegami showed how to do this in his initial reply, but he didn't explain (yet). By putting a minus sign immediately after the "%" in the format string, you tell (s)printf to left-justify the printable value within the specified field width (mnemonic: positive field width is right-justified, negative field width is left justified).

The other trick he demonstrates is the use of "*" instead of a numeric for the field width, which tells (s)printf to take the next available arg in the arg list as the field width.