but I don't know how to create a hash as a data member

    $self->{myhash} = {};
[download]

But maybe you don't even need an extra hash, as Perl objects often are hashes (like the $self here)...  so unless you have other object attributes that might get in the way, you could maybe store the key-value pairs in the object directly.

(Update)  With extra hash:

package MyClass;

sub new {
    my $class = shift;
    my $self = { @_ };
    $self->{myhash} = {};
    return bless $self, $class;
}

sub set_attr {
    my $self = shift;
    my ($key, $val) = @_;
    $self->{myhash}{$key} = $val;
}

sub get_attr {
    my $self = shift;
    my $key  = shift;
    return $self->{myhash}{$key};
}

package main;

my $obj = MyClass->new();

$obj->set_attr( foo => "bar" );

print $obj->get_attr("foo"), "\n";
[download]

Without:

package MyClass;

sub new {
    my $class = shift;
    my $self = { @_ };
    return bless $self, $class;
}

sub set_attr {
    my $self = shift;
    my ($key, $val) = @_;
    $self->{$key} = $val;
}

sub get_attr {
    my $self = shift;
    my $key  = shift;
    return $self->{$key};
}

...
[download]

use strict;
use warnings;

{package MyClass;

my @usersettings = qw|bgcolor fgcolor carmodel hairstyle sexualprefere
+nce
                       foo bar baz|;

foreach my $s (@usersettings) {
        eval  "sub setting_$s : lvalue { \$_[0]->{USERSETTINGS}{$s} }"
+;
        $@ and die "Error setting member $s : $@"
    }

sub new {
    my $class = shift;
    my %options = @_; # Remaining params are optional user settings
    #my $self = { USERSETTINGS=> {map 
    #         {exists $options{$_} ? ($_=>$options{$_}):()} 
    #          @usersettings  }};
    my $self = {};
    for my $opt(keys %options){
        grep {$opt eq $_} @usersettings or die "invalid option:$opt";
        eval "setting_$opt(\$self) ='$options{$opt}'"  ;
        $@ and die "Error setting option $opt : $@"
    }
    return bless $self,$class;
}
1;
}
#---------------------------------------
package main;

my $obj = MyClass->new( carmodel=>"BMW" );

$obj->setting_foo = "bar";

print "FOO=" . $obj->setting_foo . "; car=" 
  . $obj->setting_carmodel ."; \n";
[download]