Hello Starz, and welcome to the Monastery!

For a systematic brute-force approach, here’s a Perl script which lists the 504 possible 4-digit PINs with the constraints you describe:

use strict;
use warnings;
use Algorithm::Combinatorics qw( variations );
use constant PIN => 4;

my $count = 0;

for my $pre (variations([ 0, 2 .. 9 ], PIN - 1))
{
    print join('', @$pre), "1\t";
    ++$count;
}

print "\nTotal combinations: $count\n";
[download]

Output:

See https://en.wikipedia.org/wiki/Permutation#k-permutations_of_n and Algorithm::Combinatorics.

Hope that helps,

Smells like a homework assignment but here's a solution without any dependencies:

#!/usr/bin/perl

use strict;
use warnings;

PIN: foreach my $pin ("0000" .. "9999") {

  # Last digit is a 1
  next unless $pin =~ /1$/;

  # No repeating digits
  my %count = ();
  foreach my $digit (split(//, $pin)) {
    $count{$digit}++;
    next PIN if $count{$digit} > 1;
  }

  print $pin . "\n";
}
[download]

You could use glob to generate the numbers and grep to filter out repeats.

johngg@shiraz:~/perl/Monks$ perl -Mstrict -Mwarnings -E '
my @notOnes = ( 0, 2 .. 9 );
my $globStr = ( q|{| . join( q{,}, @notOnes ) . q|}| ) x 3 . q{1};
say for grep { ! m{(.).*\1} } glob $globStr;' | wc -l
504
[download]

I hope this is helpful.

Update: Adding a line to show what the string passed to glob looks like.

johngg@shiraz:~/perl/Monks$ perl -Mstrict -Mwarnings -E '
my @notOnes = ( 0, 2 .. 9 );
my $globStr = ( q|{| . join( q{,}, @notOnes ) . q|}| ) x 3 . q{1};
warn qq{$globStr\n};
say for grep { ! m{(.).*\1} } glob $globStr;' | wc -l
{0,2,3,4,5,6,7,8,9}{0,2,3,4,5,6,7,8,9}{0,2,3,4,5,6,7,8,9}1
504
[download]

As an aside, I wouldn't bother trying to brute force this by hand, I'd just feed the numbers into an Arduino driving 10 solenoids to press the buttons for me. Boring repetitive tasks are error prone in my (fat fingered) experience.

That's exactly why I'd use an angle grinder ...


holli

You can lead your users to water, but alas, you cannot drown them.

I don't have one, but do have plenty of the other stuff :) It's also easier to injure yourself with an angle grinder, plus it's pretty noisy and messy :P If we assume the safe operates in a reasonable fashion, that it can deal with 4 key presses a second it'd be possible to exhaust the combinations in less than 9 minutes. This also has the added advantage of not destroying the safe :) I've not seen a digital safe intended for home use that rate limits unlock attempts.