A closure is a subroutine that makes use of a lexical variable defined outside the subroutine. For example:

use v5.14;

my $foo = 40;
sub foo {
   return(2 + $foo);
}
[download]

The foo() sub is said to be a "closure", and the $foo variable has be "closed over".

When most people talk about closures though, they are usually referring to anonymous functions rather than named ones like above. Something like:

use v5.14;

sub get_counter {
   my ($count) = @_;
   my $closure = sub { $count++ };
   return $closure;
}

my $counter = get_counter(40);
my $other   = get_counter(99);
say $counter->();
say $other->();
say $counter->();
say $other->();
say $counter->();
[download]

In fact, people often use the word "closures" to refer to anonymous functions even if the function doesn't close over any variables!

This is probably due to the fact that in most programming languages (including Perl) there's no syntactic difference between defining an anonymous sub that closes over a variable verses one that does not. They are implemented subtly differently internally though as can be seen by this example:

use v5.14;
use Scalar::Util qw/refaddr/;

my @closures;
my @nonclosures;

for my $i (qw/ a b c /) {
    push @closures, sub { $i };
    push @nonclosures, sub { 42 };
}

say join "|" => map refaddr($_), @closures;
say join "|" => map refaddr($_), @nonclosures;
[download]

You'll notice that the three non-closure coderefs share a reference address. This is an optimization that Perl does. (I have at least twice had to work around this optimization by defining a dummy variable and closing over it. But then again, I do a lot of weird stuff in Perl. Most people probably never need to care about this difference.)

Anyway, coming back to Data::Form::Validator - it does accept coderefs as arguments in some places. Whether those coderefs are technically closures (i.e. they close over external variables), it probably doesn't care.

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.