When working with a large file, don't read the whole file into an array. Process the file line by line. Replace 
foreach (@list)

[download]
by 
while (<>)

[download]

Also, when populating the hash, Perl can do most of the work for you: 

push @{ $ipURL{$ip} }, $url;

[download]
This line can replace the whole if..else... construct. If the key doesn't exist in the hash, it will be created, and the dereference will create an anonymous array to which the url will be pushed. If the key exists, the url is simply pushed to the referenced array.

Whether it's also responsible for the slowdown, I have no idea.

Another place where you can avoid creating a temporary variable is the splitting. You can populate the two variables directly by subscripting the result of split: 

my ($ip, $url) = (split /,/)[7, 31];

[download]

I used the following to generate the input: 
perl -wE 'for (1..10000) {say join ",", map int rand 1000, 1..35}' > i
+nput

[download]

This was the benchmark: 

#!/usr/bin/perl
use strict;
use warnings;

open my $FH, '<', 'input' or die $!;

sub slow {
    my ($fh) = @_;
    seek $fh, 0, 0;
    my @list = <$fh>;
    my $linecounter;
    my %ipURL;
    foreach (@list) {
        $linecounter++;
        my @message=split(',',$_);
        my $ip=$message[7];
        my $url=$message[31];

        if (!(exists $ipURL{$ip})) {
            my @urlList;
            push(@urlList,$url);
            $ipURL{$ip}= \@urlList;
        } else {
            my @urlList=@{$ipURL{$ip}};
            push (@urlList,$url);
            $ipURL{$ip}=\@urlList;
        }
        if (!($linecounter % 50000)) {
                print "Lines: $linecounter\n";
        }
    }
    return \%ipURL
}

sub fast {
    my ($fh) = @_;
    my %ipURL;
    seek $fh, 0, 0;
    while (<$fh>) {
        my ($ip, $url) = (split /,/)[7, 31];
        push @{ $ipURL{$ip} }, $url;
    }
    return \%ipURL
}

use Test::More tests => 1;
is_deeply slow($FH), fast($FH), 'same';

use Benchmark qw{ cmpthese };
cmpthese(-3, {
    slow => sub { slow($FH) },
    fast => sub { fast($FH) },
});

[download]

This is the result on my machine: 

1..1
ok 1 - same
       Rate slow fast
slow 20.7/s   -- -26%
fast 27.9/s  35%   --

[download]

map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]

In reply to Re: Hash Search is VERY slow by choroba
in thread Hash Search is VERY slow by rtjensen

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.