Using unpack, hashes and Test::More:

#!/usr/bin/perl

use 5.026001;
use warnings;
use Test::More;

sub same {
    my ($s1, $s2) = @_;
    my %l1; $l1{$_}++ for unpack "(A)*" => $s1;
    my %l2; $l2{$_}++ for unpack "(A)*" => $s2;
    is_deeply (\%l1, \%l2, "'$s1' ~~~ '$s2'");
    } # same

sub diff {
    my ($s1, $s2) = @_;
    my %l1; $l1{$_}++ for unpack "(A)*" => $s1;
    my %l2; $l2{$_}++ for unpack "(A)*" => $s2;
    isnt ((join "" => map { $_, $l1{$_} } sort keys %l1),
          (join "" => map { $_, $l2{$_} } sort keys %l2),
          "'$s1' ~!~ '$s2'");
    } # diff

same ("ABBABAA", "BAABABA");
diff ("ABBABAA", "BAABBBA");
diff ("ABBABAA", "ABBABaA");
diff ("ABBABAA", "BAABBAA ");
diff ("ABBABAA", "BAABABA ");
diff ("ABBABAA", "BAABABAA");

done_testing;

[download]

-->

$ test.pl
ok 1 - 'ABBABAA' ~~~ 'BAABABA'
ok 2 - 'ABBABAA' ~!~ 'BAABBBA'
ok 3 - 'ABBABAA' ~!~ 'ABBABaA'
ok 4 - 'ABBABAA' ~!~ 'BAABBAA '
ok 5 - 'ABBABAA' ~!~ 'BAABABA '
ok 6 - 'ABBABAA' ~!~ 'BAABABAA'
1..6

[download]

edit: add example for Test2:

use 5.026001;
use warnings;
use Test2::V0;

sub same {
    my ($s1, $s2) = @_;
    my %l1; $l1{$_}++ for unpack "(A)*" => $s1;
    my %l2; $l2{$_}++ for unpack "(A)*" => $s2;
    is (\%l1, \%l2, "'$s1' ~~~ '$s2'");
    } # same

sub diff {
    my ($s1, $s2) = @_;
    my %l1; $l1{$_}++ for unpack "(A)*" => $s1;
    my %l2; $l2{$_}++ for unpack "(A)*" => $s2;
    isnt (\%l1, \%l2, "'$s1' ~!~ '$s2'");      # <- this line is now m
+uch simpler
    } # diff

same ("ABBABAA", "BAABABA");
diff ("ABBABAA", "BAABBBA");
diff ("ABBABAA", "ABBABaA");
diff ("ABBABAA", "BAABBAA ");
diff ("ABBABAA", "BAABABA ");
diff ("ABBABAA", "BAABABAA");

done_testing;

[download]

Enjoy, Have FUN! H.Merijn

In reply to Re: Check if string A and B are made up of same chars by Tux
in thread Check if string A and B are made up of same chars by harangzsolt33

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.