A straightforward way to do this is write a wanted sub to search for the pattern, and if it matches append the current filename to an array.

Here's an example: 

#!/usr/bin/perl

use warnings;
use strict;

use File::Find;
use FileHandle;

# Pattern is first argument;
# remaining arguments are file or directory names.
# Default directory is '.'

my $pat = shift;
my @results;

# Do the search
find(patternfinder(qr/$pat/,\@results),
     @ARGV?@ARGV:'.');

# Print the results
print join("\n",@results),"\n";

sub patternfinder
{
  # Generate a sub to search for a pattern and save the results
  my($pattern,$result) = @_;

  # Anonymous sub in a closure
  return sub {
    my $fh = new FileHandle $_, "r"
        or return warn "Couldn't open '$File::Find::name': $!\n";

    # Search for pattern, and add to array if it matches.
    while (<$fh>) {
      if (/$pattern/) {
        push(@$result,$File::Find::name);
        return;
      }
    }
    
    close($fh)
        or return warn "Couldn't close '$File::Find::name': $!\n";
  }
}

[download]

In reply to Re: text search in a file by sgifford
in thread text search in a file by goosefairy

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.