Just to be sure I understand you want ... You have 35 red widgets, 41 green widgets, 16 blue widgets, and you want to know the probability of getting 2 red, 1 green, 0 blue, if you were chosing 3 items randomly from all widgets? Also, the order in which they were drawn is irrelevant (drawing green,red,red is the same as red,green,red), and you are drawing without replacement.

Continuing with that example, the probability of getting green,red,red, in that order, is: 

(41/92)*(35/91)*(34/90)

[download]
All we have to do now is multiply this quantity by the number of ways to rearrange (green,red,red). In this case, there are 3 ways to rearrange them.

In general, the probability of getting x1 red, x2 green, x3 blue, etc, in some particular order, is the following: (I separated out the numerator and denominator to make it easier) 

(#red * (#red-1) * ... (#red-x1+1))
  * (#green * (#green-1) * ... (#green-x2+1) * ...

  / ( total * (total-1) * (total-2) * ... )

[download]
And the number of ways of reordering a list of x1 reds, x2 greens, x3 blues, is 
(x1+x2+x3+ ...)! / (x1! * x2! * x3! * ... )

[download]
Those exclamation points are for factorials.

As perl code, and using the example in your original post (I changed the indexing to be 0-based): 

use List::Util 'sum';

sub fact {
    my $n = shift;
    my $f = 1;
    $f *= $_ for 1 .. $n;
    $f;
}

## $n * ($n-1) * ... * ($n-$m+1)
sub lower {
    my ($n, $m) = @_;
    my $result = 1;
    $result *= $n-$_ for 0 .. $m-1;
    $result;
}

sub prob {
    my ($sizes, $sample) = @_;
    my $n = @$sizes;     ## how many types of items
    my $S = sum @$sizes; ## total number of items in the universe

    my @sampled = (0) x $n;
    my $samplesize = @$sample;
    $sampled[$_]++ for @$sample;
                         ## $sampled[x] = how many of type x
                         ##     are in this sample?

    my $total = fact($samplesize) / lower($S, $samplesize);
    $total *= lower($sizes->[$_], $sampled[$_]) / fact($sampled[$_])
        for 0 .. $n-1;

    $total;
}

## how many ways to get 2 of type 8, 1 of type 3, etc.. ?

print prob( [35000,41000,16000,18000,21000,45000,27000,10000,16000],
            [8,8,3,1,5,0,0] );

## output: 0.000397344651946416

[download]
Disclaimer: This code not tested in any great detail. Also keep in mind that all the probabilities will look small, because there are so many different events in this distribution.

Update: updated computation to account for drawing without replacement. Old code is still in comment tags. The probabilities hardly change at all since the domain is so large.

Update: fixed copy & paste error, thanks to BrowserUk++.

blokhead

In reply to Re: Sample Probabilities by blokhead
in thread Sample Probabilities by willyyam

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.