Define 'fast' and/or 'timely manner'. I guarantee the following will complete before lunch time:

use strict;
use warnings;

my @dirs;

while (my $line = <DATA>) {
    my ($indent, $entry, $isDir) = $line =~ m!^(\s*)([^/]*)(/|\\)?!;

    next unless defined $entry and length $entry;

    my $depth = length ($indent);

    if ($depth < @dirs) {
        splice @dirs, $depth, $#dirs;
    }

    if ($isDir) {
        push @dirs, $entry;
        next;
    }

    print join ('/', @dirs, $entry);
}


__DATA__
base/
 dir1/
  file1.txt
  a.png
  dir2/
   b.txt
  q.txt
 dir3/
  a.png
 f.txt

[download]

Prints:

base/dir1/file1.txt
base/dir1/a.png
base/dir1/dir2/b.txt
base/dir1/q.txt
base/dir3/a.png
base/f.txt

[download]

Update: using jdporter's assign to $#array technique the code reduces to:

use strict;
use warnings;

my @dirs;

while (my $line = <DATA>) {
    my ($indent, $entry, $isDir) = $line =~ m!^(\s*)([^/]*)(/|\\)?!;

    next unless defined $entry and length $entry;

    $#dirs = length $indent;
    $dirs[-1] = $entry;
    next if $isDir;

    print join '/', @dirs;
}

[download]
True laziness is hard work

In reply to Re: Comparing depth-indent tree to full-paths by GrandFather
in thread Comparing depth-indent tree to full-paths by Kage

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.