Update: See ikegami's response below, regarding creating a array of hashes to export your results. It is a scoping issue, but not quite what I initially thought.

Good explanation, but the conclusion is backwards. Line 10 and 28 are correct; it's line 5 that's wrong. There are multiple nics, so there should be multiple hashes. The real problem is that the function pretends there's only one. It should be returning a list of nics (list of hashes).

sub networkInfo {
    my @nics;
    my $platform = getPlatform();
    if ($platform =~ /RedHat/) {
        my $ifconfig = qx|/sbin/ifconfig|
            or die("Can't get info from Linux ifconfig: $!\n");
        for (split /(?<=\n)(?=\w)/, $ifconfig) {
            my %nic;
            ($nic{device}) = /^(eth\d)\s/
                or next;
            if (/\binet addr:([\d.]+)\s.+?:([\d.]+)\s.+?:([\d.]+)/) {
                $nic{ip}    = $1;
                $nic{bcast} = $2;
                $nic{mask}  = $3;
            }
            if (/^\s+ inet6 addr:\s*(\S+)/m) {
                $nic{ip6} = $1;
            }
            push @nics, \%nic;
        }
    } elsif ($platform =~ /SunOS/) {
        my $ifconfig = qx|/sbin/ifconfig -a|
            or die("Can't get info from Solaris ifconfig: $!\n");
        for (split /(?<=\n)(?=\w)/, $ifconfig) {
            my %nic;
            ($nic{device}) = /^(fjgi\d)\s/
                or next;
            if (/\binet addr:([\d.]+)\s.+?:([\d.]+)\s.+?:([\d.]+)/) {
                $nic{ip}    = $1;
                $nic{bcast} = $2;
                $nic{mask}  = $3;
            }
            if (/^\s+ inet6 addr:\s*(\S+)/m) {
                $nic{ip6} = $1;
            }
            push @nics, \%nic;
        }    
    }
    return @nics;
}

for my $nic (networkInfo()) {
    print(join( "\t",
        map $_//'[undef]',
        @{$nic}{qw( device ip ipv6 bcast mask )} ), "\n");
}
[download]

Update: Cleaned up opening paragraph.
Update: Second push discovered ability to turn invisible. Added anti-invisibility field to post so it's visible again.

I am getting an error when I try to run this code. It says

Search pattern not terminated at ./sec-test.pl line 166 (#1) (F) The lexer couldn't find the final delimiter of a // or m{} construct. Remember that bracketing delimiters count nesting level. Missing the leading $ from a variable $m may cause this error. Note that since Perl 5.9.0 a // can also be the defined-or construct, not just the empty search pattern. Therefore code written in Perl 5.9.0 or later that uses the // as the defined-or can be misparsed by pre-5.9.0 Perls as a non-terminated search pattern. Uncaught exception from user code: Search pattern not terminated at ./sec-test.pl line 166. at ./sec-test.pl line 166

line 166 is the map $_//'[undef]', line

Also how would I return to main so I could run the following code section, or code similar to what I have below?

my %nicdata = networkInfo($platform);

for (@nicdata) {
    print "Device: $nic{device} has the IP Address of $nic{ip}\n\tMask
+: $nic{mask}\n\tBroadcast: $nic{bcast}\n";
    print "Device: $nic{device} also has IPv6 address of $nic{ip6}\n";
}
[download]

As likely steps, I would verify that $platform_in contains what you think it should. It looks as if you never modify %nic which is why Data::Dumper shows it as empty. Note also how none of your print statements appear in the output.

This leads me back to some old IBM research I remember that every if statement needs an else branch, as I remember them finding a high likelyhood that an if without the corresponding else was an error. In your case, you should add a final else branch to your chain of if statements that check the operating systems, and in that else branch either die or at least output something that you don't know what to do with $platform_in.