use strict;
use warnings;
use XML::LibXML;
use Text::CSV;

open my $dip_file, ">>", "C:/director/DIPFILE.TXT"
    or die "Couldn't open DIP file for appending: $!";

open my $dip_log, ">>", "C:/director/DIPLOG.TXT"
    or die "Couldn't open DIP log for appending: $!";

my $csv = Text::CSV->new;

# glob is a built-in, you don't need to "use File::Glob."
my @dipfile = glob('C:/director/*.xml');

my $parser = XML::LibXML->new();
# set options for $parser here if needed, like $parser->recover(1) for
# messed up XML.

for my $xml_file ( @dipfile ) {
    my $doc = $parser->parse_file($xml_file);

    my ( $default_name ) = $doc->findnodes("//defaultName");
    my ( $default_description ) = $doc->findnodes("//defaultDescription");
    my ( $report_execution_time ) = $doc->findnodes("//reportExecutionTime");

    $csv->combine( $xml_file,
                   $default_name ? $default_name->textContent : "",
                   $default_description ? $default_description->textContent : "",
                   $report_execution_time ? $report_execution_time->textContent : "",
                   );

    # Update:
    print $csv->string, "\n"; # To see it in the terminal.
    $dip_file->print( $csv->string, "\n" );
    $dip_log->print( $csv->string, "\n" );
}