#!/usr/lib/perl
use strict;
use warnings;
use Carp;
use File::Find;
use File::Spec::Functions qw( canonpath );
use XML::LibXML::Reader;
use Digest::MD5 'md5';

if ( @ARGV == 0 ) {
    push @ARGV, "C:/file/dir";
    warn "Using default path $ARGV[0]\n  Usage: $0  path ...\n";
}

# open an output file whose name won't be found by File::Find
open( my $allxml, '>', "all_shiporders.xml.combined" )
    or die "can't open output xml file for writing: $!\n";
print $allxml '<?xml version="1.0" encoding="UTF-8"?>',
    "\n<shiporder xmlns:xsi=\"http://www.w3.org/2001/XMLSchema-instance\">\n";

my %shipto_md5;

find(
    sub {
        return unless ( /[.]xml\z/i and -f );
        extract_information();
        return;
    },
    @ARGV
);

print $allxml "</shiporder>\n";

sub extract_information {
    my $path = $_;
    if ( my $reader = XML::LibXML::Reader->new( location => $path )) {
        while ( $reader->nextElement( 'shipto' )) {
            my $elem = $reader->readOuterXml();
            my $md5 = md5( $elem );
            print $allxml $reader->readOuterXml() unless ( $shipto_md5{$md5}++ );
        }
    }
    return;
}

##</code><code>##

==> j1.xml <==
<?xml version="1.0" encoding="UTF-8"?>
<shiporder xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<shipto>
    <name>johan</name>
    <address>Langgt 23</address>
</shipto>
</shiporder>

==> j2.xml <==
<?xml version="1.0" encoding="UTF-8"?>
<shiporder xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<shipto>
    <name>benny</name>
    <address>galve 23</address>
</shipto>
</shiporder>

==> j3.xml <==
<?xml version="1.0" encoding="UTF-8"?>
<shiporder xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<shipto>
    <name>kent</name>
    <address>vadrss 25</address>
</shipto>
</shiporder>

==> j4.xml <==
<?xml version="1.0" encoding="UTF-8"?>
<shiporder xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<shipto>
    <name>benny</name>
    <address>galve 23</address>
</shipto>
</shiporder>

==> j5.xml <==
<?xml version="1.0" encoding="UTF-8"?>
<shiporder xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<shipto>
    <name>stewart</name>
    <address>vadrss 25</address>
</shipto>
</shiporder>

##</code><code>##


<?xml version="1.0" encoding="UTF-8"?>
<shiporder xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<shipto>
    <name>johan</name>
    <address>Langgt 23</address>
</shipto><shipto>
    <name>benny</name>
    <address>galve 23</address>
</shipto><shipto>
    <name>kent</name>
    <address>vadrss 25</address>
</shipto><shipto>
    <name>stewart</name>
    <address>vadrss 25</address>
</shipto></shiporder>