What I want to generate is this. (I also need to keep the row descriptors : run1, run2 etc)

There are many ways to skin this cat and the cat isn't happy about it.

#!/usr/bin/perl -w 
use strict;

while (my $line=<DATA>){
      chomp $line; 
      my($run,@sw)=split(/[\s]+/,$line);
      my @switches=();
      $switches[$_] = 0 foreach (0..5);  # initialize switch array
      $switches[$_ -1]=1 foreach (@sw);
      printf "%s %s\n",$run,join(" ",@switches);
          
}

exit(0);
__END__
run1 2 4
run2 1 6
run3 1
run4 1 3
run5 2 5
[download]

while (my $line = <>) {
    chomp $line;
    my (@columns) = split ' ', $line;
    my @switches = (0) x 6;
    unshift @switches, shift @columns; # runX kept.
    $switches[$_] = 1 for @columns;
    print join(' ', @switches), "\n";
}
[download]

Here a version if the number of switches is not known upfront.

use strict;
use warnings;

my $max = 0;
my $data;
while(<DATA>){
        chomp;
        my @array = split /\s/;
        my @line = ( shift @array );
        $line[$_] = 1 for @array;  
        $max = @line > $max ? @line : $max;
        push @$data, \@line;
}
for my $row (@$data) {
        print $row->[$_]//0 ," " for (0..$max-1);
        print "\n";
}

__DATA__
run1 2 4
run2 1 6
run3 1
run4 1 3
run5 2 5
[download]

...and one version based on regex if the number of switches is known:

use strict;
use warnings;

my $n_switches = 6;
while(<DATA>){
  my $last = 0;
  s/\s(\d+)/my $d = $1-$last-1; $last = $1; " 0"x$d." 1" /ge;
  s/\n/" 0" x ($n_switches-$last)."\n"/e;
  print;
}

__DATA__
run1 2 4
run2 1 6
run3 1
run4 1 3
run5 2 5
[download]

while (<DATA>) {
  my @array = (0) x 7;

  ($array[0], my @pos) = split /\s+/;

  @array[@pos] = (1) x @pos;        
  
  print "@array\n";                      
}

__DATA__
run1 2 4
run2 1 6
run3 1
run4 1 3
run5 2 5
[download]

OUTPUT

run1 0 1 0 1 0 0
run2 1 0 0 0 0 1
run3 1 0 0 0 0 0
run4 1 0 1 0 0 0
run5 0 1 0 0 1 0
[download]

What have you tried?