edit

  DB<126> @arr = (("A") x 2, ("T") x 2, ("C") x 3, ("G") x 3);
 => ("A", "A", "T", "T", "C", "C", "C", "G", "G", "G")
[download]

update

see perlop#Multiplicative-Operators "repetition operator" for details

Binary "x" is the repetition operator. In scalar context or if the left operand is not enclosed in parentheses, it returns a string consisting of the left operand repeated the number of times specified by the right operand. In list context, if the left operand is enclosed in parentheses or is a list formed by "qw/STRING/", it repeats the list. If the right operand is zero or negative, it returns an empty string or an empty list, depending on the context.

but I have to admit it sounds confusing ... :)

update

hmm should maybe be rephrased:

  DB<129> $arr = ("G") x 3;
 => "GGG"
[download]

always a string in scalar context!

perfect thanks.

use warnings;
use strict;

my @arr = (("A") x 20, ("T") x 20, ("C") x 30, ("G") x 30);
print scalar @arr, "\n";

__END__

100
[download]

awesome. I wasn't able to properly search for it in the documentation. Thanks

> I wasn't able to properly search for it in the documentation.

see Re: Perldoc Keyword Search (update4)

> pd x
Matches for x found in :
 /usr/share/perl/5.10/pod/perlop.pod
[download]

pager are opened for each match and files are scolled to the right place with highlighted keyword

       ">>> X<x> <<<" in perlop

       Binary "x" is the repetition operator.  In scalar context or if
+ the
       left operand is not enclosed in parentheses, it returns a strin
+g
       consisting of the left operand repeated the number of times spe
+cified
       by the right operand.  In list context, if the left operand is 
+enclosed
       in parentheses or is a list formed by "qw/STRING/", it repeats 
+the
       list.  If the right operand is zero or negative, it returns an 
+empty
       string or an empty list, depending on the context.

           print '-' x 80;             # print row of dashes

           print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over

           @ones = (1) x 80;           # a list of 80 1's
           @ones = (5) x @ones;        # set all elements to 5
[download]

HTH! =)

Cheers Rolf

_{(addicted to the Perl Programming Language and ☆☆☆☆ :)}

> I wasn't able to properly search for it in the documentation.

Another approach: type "x" in the search-field here: http://perldoc.perl.org and you'll get

• x
• xor

These operators are documented in perlop

Cheers Rolf

_{(addicted to the Perl Programming Language and ☆☆☆☆ :)}

I.e.,

my @arr = (('A') x 20, ('T') x 20, ('C') x 30, ('G') x 30);
[download]

Update: Or perhaps:

my @arr =
  map { ($_->[0]) x $_->[1] }
  [A => 20], [T => 20], [C => 30], [G => 30]
  ;
[download]

Jeri:

A method that's pretty close to what you originally posted:

...roboticus

When your only tool is a hammer, all problems look like your thumb.

Another variation using an inner map instead of the list multiplier and a list of hashrefs as the template.

$ perl -Mstrict -Mwarnings -E '
my @array =
   map {
       my( $key ) = keys %$_;
       map $key, 1 .. $_->{ $key };
       } { A => 3 }, { T => 4 }, { C => 2 }, { G => 5 };

say for @array;'
A
A
A
T
T
T
T
C
C
G
G
G
G
G
$
[download]

I hope this is of interest.

Update: Another couple of variants:-

$ perl -Mstrict -Mwarnings -E '
my @array =
   map {
       ( keys %$_ )
       x           
       do { my( $v ) = values %$_; $v }
       } { A => 3 }, { T => 4 }, { C => 2 }, { G => 5 };
                
say for @array;'
...
[download]

$ perl -Mstrict -Mwarnings -E '
my @array =
   map {
       my( $k, $v ) = each %$_;
       ( $k ) x $v;
       } { A => 3 }, { T => 4 }, { C => 2 }, { G => 5 };
                                                        
say for @array;'
...
[download]

I don't know if this is mannerism or minimalism ;-)

#!/usr/bin/env perl                                                   
+                              

use strict;
use warnings;

# my @array = split('',  join "", ( "A" x 20, "T" x 20, "C" x 30, "G" 
+x 30 ) );

# my @array = split '', join '', ( "A" x 20, "T" x 20, "C" x 30, "G" x
+ 30 );

my @array = split '', join '', "A" x 20, "T" x 20, "C" x 30, "G" x 30;

print  scalar @array . qq(\n);

print for @array;

__END__
[download]

But it works.

Update: No parentheses.

Regards, Karl