Use different frames to separate widgets in columns when you are using pack, or use other geometry managers like grid, frame or place. A good source of inspiration is the widget demo script that comes with TK (enter 'widget' in the console).

The anchor option is for alignment.

use 5.010;                      # for say
use strict;
use warnings;
use Tk;

my $main  = MainWindow->new();
my $label = $main->Label( -text => "Presence Check" )->pack();

my $opt_ft  = [qw/-side top -expand 1 -fill both/];
my $opt_flr = [qw/-side left -expand 1 -fill both/];
my $opt_fb  = [qw/-side bottom -expand 1 -fill both/];
my $opt_c   = [qw/-side top -pady 2 -anchor w/];

my $fr_top   = $main->Frame()->pack(@$opt_ft);
my $fr_top_l = $fr_top->Frame()->pack(@$opt_flr);
my $fr_top_r = $fr_top->Frame()->pack(@$opt_flr);
my $fr_bot   = $main->Frame()->pack(@$opt_fb);

my ( $vbutton1, $vbutton2, $vbutton3 ) = ( 'OFF', 'ON', 'OFF' );
my $b1 = [
    [ 'button1', 'button 1', \$vbutton1, 'OFF', 'ON' ],
    [ 'button2', 'button 2', \$vbutton2, 'OFF', 'ON' ],
    [ 'button3', 'button 3', \$vbutton3, 'OFF', 'ON' ],
];

foreach my $btn (@$b1) {
    $fr_top_l->Checkbutton(
        -text     => $btn->[1],
        -variable => \$btn->[2],
        -offvalue => $btn->[3],
        -onvalue  => $btn->[4],
    )->pack(@$opt_c);
}

my ( $vbutton4, $vbutton5 ) = ( 'ON', 'OFF' );
my $b2 = [
    [ 'button4', 'button 4', \$vbutton4, 'OFF', 'ON' ],
    [ 'button5', 'button 5', \$vbutton5, 'OFF', 'ON' ],
];

foreach my $btn (@$b2) {
    $fr_top_r->Checkbutton(
        -text     => $btn->[1],
        -variable => \$btn->[2],
        -offvalue => $btn->[3],
        -onvalue  => $btn->[4],
    )->pack(@$opt_c);
}

my $button = $fr_bot->Button(
    -text    => "Exit",
    -command => \&exit_button
)->pack(@$opt_ft);

MainLoop();

sub exit_button {
    foreach my $btn (@$b1) {
        say "- $btn->[0]: $btn->[1] -> ${$btn->[2]}";
    }
    foreach my $btn (@$b2) {
        say "- $btn->[0]: $btn->[1] -> ${$btn->[2]}";
    }
    $main->destroy;
}
[download]

Regards, Stefan.

G'day michael99,

I can't tell exactly the layout you're aiming for. A little bit of simple ASCII art can help to explain what you want. For instance, you currently have something along these lines:

+--+
|A1|
|A2|
|A3|
|B1|
|C1|
|C2|
+--+
[download]

Do any of these look like what you ultimately want?

+--------+  +--------+  +-----+
|A1|A2|A3|  |A1|B1|C1|  |A1|B1|
|B1|  |  |  |A2|  |C2|  |A2|C1|
|C1|C2|  |  |A3|  |  |  |A3|C2|
+--------+  +--------+  +-----+
[download]

Here's a couple of tentative suggestions:

• Perhaps changing the geometry manager from Tk::pack to Tk::grid might be helpful.
• As you talk about the checkbuttons being in columns, perhaps Tk::HList would be a useful option. If you run the widget demo — in case you don't know, that's just widget from the command line — you'll find an example (GUI demo and code) of doing this. It's under:
    Tix Widgets
      ...
      Multicolumn listbox ...

With more information from you, better suggestions may present themselves.

Here's another frames-within-frames approach.
tk_multi_check_2.pl:

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11115774
use warnings;
use Tk;

my $mw = MainWindow->new;
$mw->geometry( '+500+300' );

my $list = $mw->Frame->pack;
$mw->Button(-text => 'Exit', -font => 24,
  -command => sub {$mw->destroy},
  )->pack(-fill => 'x');

# FIXME - of course, change to list of your own data...
my @listdata = map { text => "Document A$_ (docx, pdf)",
  var => \$a, on => "APRESENT", off => "AABSENT" }, 1 .. 25;

my $maxrows = 10;
my $row = 1;
my $col = 1;
for my $datum ( @listdata )
  {
  $list->Checkbutton(
    -variable => $datum->{var},
    -onvalue => $datum->{on},
    -offvalue => $datum->{off},
    )->grid(-row => $row, -column => $col + 1);
  $list->Label( -text => $datum->{text}, -font => 24,
    )->grid(-row => $row, -column => $col, -sticky => 'e');
  if( ++$row > $maxrows )
    {
    $row = 1;
    $col += 2;
    }
  }

MainLoop;
[download]

Re^3: Aligning Tk Checkboxes

Tk::CheckbuttonGroup