But I guess there's a simple (if verbose) way to add them, regardless of how it was created, because the right side of a hash assignment is really just a list, and values later in the list supersede those earlier in the list:

%the_hash = (
  day     => '-',
  Balance => '-',
  payment => '-',
  Total   => '-',
  %the_hash
);
[download]

$ perl -MData::Printer -E "%h = (day => 1, Total => 2); %h = (day => '
+-', Balance => '-', payment => '-', Total => '-', %h); p %h;"
{
    Balance   "-",
    day       1,
    payment   "-",
    Total     2
}
[download]

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11118040
use warnings;

my %hash =
  (
  1 => { Balance => 183.57, day => 1, payment => 0, Total => 0 },
  4 => { Balance => 12.86, day => 4, payment => 0, Total => 0 },
  );

use Data::Dump 'dd'; dd \%hash;

for my $day ( 1 .. 4 )
  {
  $hash{$day} = { Balance => '-', day => $day, payment => '-', Total =
+> '-' ,
    %{ $hash{$day} // {} } };
  }

use Data::Dump 'dd'; dd \%hash;
[download]

Outputs:

{
  1 => { Balance => 183.57, day => 1, payment => 0, Total => 0 },
  4 => { Balance => 12.86, day => 4, payment => 0, Total => 0 },
}
{
  1 => { Balance => 183.57, day => 1, payment => 0, Total => 0 },
  2 => { Balance => "-", day => 2, payment => "-", Total => "-" },
  3 => { Balance => "-", day => 3, payment => "-", Total => "-" },
  4 => { Balance => 12.86, day => 4, payment => 0, Total => 0 },
}
[download]

It looks as if you might be starting with an array of hashes (an AoH) and you want to add some elements (additional hashes) after the first element of the existing array. If so, one way:

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my @ra = (
   { 'day' => 1, 'Balance' => '183.57', 'payment' => 0, 'Total' => 0, 
+},
   { 'day' => 4, 'Balance' => '12.86',  'payment' => 0, 'Total' => 0, 
+},
   );
 dd \@ra;
 ;;
 my @add_after_first =
   map { { 'day' => $_, qw(Balance -  payment -  Total -) } } 2, 3;
 ;;
 splice @ra, 1, 0, @add_after_first;
 dd \@ra;
"
[
  { Balance => "183.57", Total => 0, day => 1, payment => 0 },
  { Balance => "12.86", Total => 0, day => 4, payment => 0 },
]

[
  { Balance => "183.57", Total => 0, day => 1, payment => 0 },
  { Balance => "-", Total => "-", day => 2, payment => "-" },
  { Balance => "-", Total => "-", day => 3, payment => "-" },
  { Balance => "12.86", Total => 0, day => 4, payment => 0 },
]
[download]

Update: A variation. Factoring out the null items list into the  NULL_ITEMS constant may be useful in other situations in your code. (Update: Oops... I just noticed that the "null" value I'm using in this example is, for some reason, a  ' (single-quote) instead of a  - (hyphen). Oh, well. I think you can get the idea, so I'm not going to change the code.)

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"use constant NULL_ITEMS => map { $_ => '\'' } qw(Balance Total day pa
+yment);
 ;;
 my @ra = (
   { 'day' => 1, 'Balance' => '183.57', 'payment' => 0, 'Total' => 0, 
+},
   { 'day' => 4, 'Balance' => '12.86',  'payment' => 0, 'Total' => 0, 
+},
   );
 dd \@ra;
 ;;
 splice @ra, 1, 0, map { { NULL_ITEMS, 'day' => $_ } } 2, 3;
 dd \@ra;
"
[
  { Balance => "183.57", Total => 0, day => 1, payment => 0 },
  { Balance => "12.86", Total => 0, day => 4, payment => 0 },
]

[
  { Balance => "183.57", Total => 0, day => 1, payment => 0 },
  { Balance => "'", Total => "'", day => 2, payment => "'" },
  { Balance => "'", Total => "'", day => 3, payment => "'" },
  { Balance => "12.86", Total => 0, day => 4, payment => 0 },
]
[download]

G'day Sami_R,

"... set hash values to '-', is there any simplest way of implementing this, please."

You can assign to multiple keys at the same time using a hash slice (see "perldata: Slices"). You can assign multiple, identical values using the repetition operator (see "perlop: Multiplicative Operators").

As already pointed out, information from you is missing. The following code should give you an idea of a technique you might employ; of course, it's impossible to even suggest implementation details.

$ perl -e '
    my @hashes;
    my @days = ([1,2,3], [], [], [4,5,6]);
    for (0 .. $#days) {
        my %x = (day => 1+$_);
        @x{qw{bal pay tot}}
            = @{$days[$_]} ? @{$days[$_]} : ("-") x 3;
        push @hashes, \%x;
    }
    use Data::Dump;
    dd \@hashes;
'
[
  { bal => 1, day => 1, pay => 2, tot => 3 },
  { bal => "-", day => 2, pay => "-", tot => "-" },
  { bal => "-", day => 3, pay => "-", tot => "-" },
  { bal => 4, day => 4, pay => 5, tot => 6 },
]
[download]

use strict;
use warnings;


my $nullRecord_ref = {'Balance' => '-', 'payment' => '-', 'Total' => '
+-' };

my %hash_of_days = 
(
   'day1' => {'Balance' => '183.57', 'payment' => 0, 'Total' => 0, },
   'day4' => {'Balance' => '12.86',  'payment' => 0, 'Total' => 0, },
);

foreach my $day (1..5,123)
{
   my %result = searchDB (\%hash_of_days, $day);
   print "Day = $day:\n";
   print "  ",$_ => "  ".$result{$_},"\n" foreach (keys %result);
}

sub searchDB
{
   my($DBref, $day) = @_;
   my %result;
   
   %result = %$nullRecord_ref;
   %result = %{$DBref->{"day$day"}} if exists $DBref->{"day$day"};
   return %result;
}

__END__
Prints:
Day = 1:
  Balance  183.57
  payment  0
  Total  0
Day = 2:
  payment  -
  Total  -
  Balance  -
Day = 3:
  Total  -
  payment  -
  Balance  -
Day = 4:
  payment  0
  Total  0
  Balance  12.86
Day = 5:
  Balance  -
  payment  -
  Total  -
Day = 123:
  Total  -
  payment  -
  Balance  -
[download]