That's actually just another syntax for FILEHANDLE->print(LIST) a.k.a. "indirect method call".

So creating your own methods would do and

• a bareword OTHER_QUEUE must be a package
• a var $other_queue hold an object or a class-name (= package).

But are you sure you wanna go such exotic ways for just a little syntactic sugar?

IMHO it's better to simply write

• queue other => $job;

and checking if queue() had 1 or 2 args.

are you sure you wanna go such exotic ways for just a little syntactic sugar?

Agreed. I certainly wouldn't embrace barewords when defining a new module's interface, as described in more detail at: Re: Indirect Object Syntax (Parsing Barewords and Quoting References)

That's actually just another syntax for FILEHANDLE->print(LIST) a.k.a. "indirect method call".

It's not. print, as an operator, can have whatever syntax it wants. And while print FH ... looks like an indirect method call, it's not. It's simply the print function/op. This means it doesn't call the print of IO::File or whatever package *FH{IO} is blessed into like FH->print( ... ) does.

But are you sure you wanna go such exotic ways for just a little syntactic sugar?

Note that indirect method calls are disabled in v5.36 of the language (i.e. when you use use v5.36;). It's not the time start using them!

I seem to remember that I was able to overide say in this way, but I can't find the thread anymore.

Cheers Rolf
_{(addicted to the 𐍀𐌴𐍂𐌻 Programming Language :)
Wikisyntax for the Monastery}

G'day mikkoi,

"I would like to create my own subroutines which would work the same way as print FILEHANDLE LIST works."

There's a big difference between "works the same" (as suggested by your title) and "looks the same" (as suggested by your example).

If you simply want an optional first argument which is a filehandle-like object, you can do something like this (pm_11152428_opt_arg.pl):

#!/usr/bin/env perl

use strict;
use warnings;

queue("This is: queue(string)\n");
queue('This is: ', "queue(string, string)\n");
queue(\*STDERR, "This is: queue(\\*STDERR, string)\n");
queue(\*STDERR, 'This is: ', "queue(\\*STDERR, string, string)\n");

sub queue {
    my $Q = ref $_[0] eq 'GLOB' ? shift : \*STDOUT;
    my @list = @_;
    $Q->print(@list);
    return;
}
[download]

Output everything:

$ ./pm_11152428_opt_arg.pl
This is: queue(string)
This is: queue(string, string)
This is: queue(\*STDERR, string)
This is: queue(\*STDERR, string, string)
[download]

Output just STDOUT:

$ ./pm_11152428_opt_arg.pl 2>/dev/null
This is: queue(string)
This is: queue(string, string)
[download]

Output just STDERR:

$ ./pm_11152428_opt_arg.pl 1>/dev/null
This is: queue(\*STDERR, string)
This is: queue(\*STDERR, string, string)
[download]

Of course, if $job were a globref, you'd have to rethink that strategy; however, your question suggests that's not the case.

If you want "looks the same", then that is called indirect object syntax (as ++LanX has already pointed out) and there are reasons not to use this form.

perlobj: Invoking Class Methods: Indirect Object Syntax

The first line of this section starts with the emboldened text: "Outside of the file handle case, use of this syntax is discouraged as it can confuse the Perl interpreter. ..."

perl5360delta: use v5.36

This syntax is disabled by default in v5.36.0. You can read the full text but the key elements are: "The 5.36 bundle also disables the features indirect ... will forbid ... the use of "indirect" method calls ... that cause more trouble than they're worth."

In line with the documentation, I strongly recommend that you do not use this syntax.

Something like this ?

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11152428
use warnings;

my $job = 'something';

sub queue
  {
  print "simple queue: '@_'\n";
  }

sub OTHER_QUEUE::queue
  {
  shift;
  print "a different queue: '@_'\n";
  }

queue $job;
queue OTHER_QUEUE $job;
[download]

Outputs:

simple queue: 'something'
a different queue: 'something'
[download]