My guess is that File::Find vigorously protects you from doing what you want.

After closely inspecting your non-existent SSCCE and taking an enormous leap of intuition, here's an SSCCE with a couple of choices for what I think your non-existent SSCCE shows you want :)

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11159091
use warnings;
use Path::Tiny;

my $dir = path('a');
$dir->remove_tree;
path('a/b/c')->mkdir;
path('a/b/c/file.tcl')->touch;
symlink 'b', 'a/sym1';
symlink 'c', 'a/b/sym2';
system 'echo from the system tree command to show file structure;tree'
+;

print "\n";

my @folders = 'a'; # FIXME set to base of folder(s)
while( my $path = shift @folders )
  {
  push @folders, grep -d, <$path/*>;
  print "$0: $_\n" for <$path/*.tcl>;
  }

print "\n";

path('a')->visit(sub{/\.tcl$/ and print "Path::Tiny::visit: $_\n"},
  {recurse => 1, follow_symlinks => 1}
  );

print "\n";

use File::Find;
find ({wanted => sub {/\.tcl$/ and print "File::Find $File::Find::name
+\n" },
  follow_skip => 2 }, 'a');
[download]

which outputs:

from the system tree command to show file structure
.
`-- a
    |-- b
    |   |-- c
    |   |   `-- file.tcl
    |   `-- sym2 -> c
    `-- sym1 -> b

6 directories, 1 file

../2perltree.pl: a/b/c/file.tcl
../2perltree.pl: a/b/sym2/file.tcl
../2perltree.pl: a/sym1/c/file.tcl
../2perltree.pl: a/sym1/sym2/file.tcl

Path::Tiny::visit: a/sym1/c/file.tcl
Path::Tiny::visit: a/sym1/sym2/file.tcl
Path::Tiny::visit: a/b/c/file.tcl
Path::Tiny::visit: a/b/sym2/file.tcl

File::Find a/b/c/file.tcl
[download]

This output was generated on an ArchLinux system. It's possible that Find::File for the OS on your (unspecified) system (OS/2 BSD4.2 RSX-11M MVS Multics etc) may behave differently.