mrguy123 has asked for the wisdom of the Perl Monks concerning the following question:

Hi monks
Haven't asked a question in a while but this is an interesting case (also I really need to solve it).
Say I have a list of hashes, for example: 
@students = (
{
   name  => "Guy",
   college => "Yale",
},
{
   name  => "Gil",
   college => "Harvard",
},
{
   name  => "Gil",
   college => "Harvard",
},
);

[download]
I want to make this list unique, meaning it needs to look like this: 
@uniq_students = (
{
   name  => "Guy",
   college => "Yale",
},
{
   name  => "Gil",
   college => "Harvard",
},
);

[download]
List::MoreUtils::uniq doesn't work on lists of hashes so that's a no go. I can do it for one hash key (below) but for 2 or more keys it's tricky 
##Solution for one hash key
my @unique = do { my %seen; grep { !$seen{$_->{name}}++ } @students};

[download]
Of course I can find a workaround (e.g. make each hash into a string and then sort ...) but I would like to try and find something better (and shorter) if possible
Any ideas?


Everybody seems to think I'm lazy
I don't mind, I think they're crazy

Replies are listed 'Best First'.
Re: Unique list of hashes
by hdb (Monsignor) on Mar 02, 2015 at 11:29 UTC

    Like this? 

    use strict;
use warnings;
use Data::Dumper;
my @students = (
    {
    name  => "Gil",
    college => "Yale",
    },
    {
    name  => "Gil",
    college => "Harvard",
    },
    {
    name  => "Gil",
    college => "Harvard",
    },
    );
my @unique = do { 
    my( %seenName, %seenCollege ); 
    grep { !$seenName{$_->{name}}++ or !$seenCollege{$_->{college}}++ 
+} @students};
print Dumper \@unique;

    [download]

    UPDATE: Sorry, got that wrong. It should be:

    my @unique = do { 
    my %seen; grep { !$seen{$_->{name}}{$_->{college}}++ } @students};

    [download]
[reply]
[d/l]
[select]
      Nice!!
      I was actually thinking along the line of your first solution, but couldn't get figure out how to take care of the "or". I think this is just what I need.
      Thanks!
[reply]
Re: Unique list of hashes
by LanX (Saint) on Mar 02, 2015 at 11:37 UTC
    As a side note: I suggest you better try to find a unique identifier for each student and restructure your data:

    %students = (
  1111 => {
    name  => "Guy",
    college => "Yale",
  },

  2222 => {
    name  => "Gil",
    college => "Harvard",
  },
);

    [download]

    Keep in mind that equally named persons are not that rare, even in the same university.

    Cheers Rolf
    (addicted to the Perl Programming Language and ☆☆☆☆ :)

    PS: Je suis Charlie!

[reply]
[d/l]
Re: Unique list of hashes
by parv (Parson) on Mar 02, 2015 at 11:41 UTC

    Make a key out of combined values to search for uniqueness ... 

    @uniq =
  grep
  !$seen{ join '' , sort values %{ $_ } }++
  , @list
  ;

    [download]
[reply]
[d/l]
      Make a key out of combined values to search for uniqueness ... @uniq = grep !$seen{ join '' , sort values %{ $_ } }++, @list;

      So these are all the same?

      my @list = (
    { foo=>'bar', quz=>'baz' },
    { abc=>'bar', def=>'baz' },
    { ijk=>'ba', xyz=>'rbaz' },
    { r=>'ba', s=>'rba', t=>'z' },
    { x=>'barbaz' },
);

      [download]
[reply]
[d/l]
[select]

        Using a delimiter that cannot appear in the values would be useful... like a pipe or such.

[reply]

        Nope, not all are same as you already know. hdb has already given slightly complicated method to satisfy your situation.

[reply]

Back to Seekers of Perl Wisdom